CMakeLists.txt 15 KB
Newer Older
Jason Rhinelander's avatar
Jason Rhinelander committed
1
2
3
4
5
6
7
# CMakeLists.txt -- Build system for the pybind11 test suite
#
# Copyright (c) 2015 Wenzel Jakob <wenzel@inf.ethz.ch>
#
# All rights reserved. Use of this source code is governed by a
# BSD-style license that can be found in the LICENSE file.

8
cmake_minimum_required(VERSION 3.4)
9

10
# The `cmake_minimum_required(VERSION 3.4...3.18)` syntax does not work with
Henry Schreiner's avatar
Henry Schreiner committed
11
12
# some versions of VS that have a patched CMake 3.11. This forces us to emulate
# the behavior using the following workaround:
13
if(${CMAKE_VERSION} VERSION_LESS 3.18)
Henry Schreiner's avatar
Henry Schreiner committed
14
  cmake_policy(VERSION ${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION})
15
else()
Henry Schreiner's avatar
Henry Schreiner committed
16
  cmake_policy(VERSION 3.18)
17
18
endif()

19
20
21
22
23
24
25
26
# Only needed for CMake < 3.5 support
include(CMakeParseArguments)

# Filter out items; print an optional message if any items filtered
#
# Usage:
#   pybind11_filter_tests(LISTNAME file1.cpp file2.cpp ... MESSAGE "")
#
27
macro(pybind11_filter_tests LISTNAME)
28
29
30
31
32
33
34
35
36
37
38
39
40
41
  cmake_parse_arguments(ARG "" "MESSAGE" "" ${ARGN})
  set(PYBIND11_FILTER_TESTS_FOUND OFF)
  foreach(filename IN LISTS ARG_UNPARSED_ARGUMENTS)
    list(FIND ${LISTNAME} ${filename} _FILE_FOUND)
    if(_FILE_FOUND GREATER -1)
      list(REMOVE_AT ${LISTNAME} ${_FILE_FOUND})
      set(PYBIND11_FILTER_TESTS_FOUND ON)
    endif()
  endforeach()
  if(PYBIND11_FILTER_TESTS_FOUND AND ARG_MESSAGE)
    message(STATUS "${ARG_MESSAGE}")
  endif()
endmacro()

42
43
44
45
46
47
48
49
macro(possibly_uninitialized)
  foreach(VARNAME ${ARGN})
    if(NOT DEFINED "${VARNAME}")
      set("${VARNAME}" "")
    endif()
  endforeach()
endmacro()

50
51
52
53
54
55
# New Python support
if(DEFINED Python_EXECUTABLE)
  set(PYTHON_EXECUTABLE "${Python_EXECUTABLE}")
  set(PYTHON_VERSION "${Python_VERSION}")
endif()

56
57
# There's no harm in including a project in a project
project(pybind11_tests CXX)
Jason Rhinelander's avatar
Jason Rhinelander committed
58

Henry Schreiner's avatar
Henry Schreiner committed
59
60
61
# Access FindCatch and more
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/../tools")

Henry Schreiner's avatar
Henry Schreiner committed
62
option(PYBIND11_WERROR "Report all warnings as errors" OFF)
63
option(DOWNLOAD_EIGEN "Download EIGEN (requires CMake 3.11+)" OFF)
64
option(PYBIND11_CUDA_TESTS "Enable building CUDA tests (requires CMake 3.12+)" OFF)
Henry Schreiner's avatar
Henry Schreiner committed
65
66
67
set(PYBIND11_TEST_OVERRIDE
    ""
    CACHE STRING "Tests from ;-separated list of *.cpp files will be built instead of all tests")
68
69
70
set(PYBIND11_TEST_FILTER
    ""
    CACHE STRING "Tests from ;-separated list of *.cpp files will be removed from all tests")
Jason Rhinelander's avatar
Jason Rhinelander committed
71

72
if(CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_SOURCE_DIR)
Henry Schreiner's avatar
Henry Schreiner committed
73
74
75
  # We're being loaded directly, i.e. not via add_subdirectory, so make this
  # work as its own project and load the pybind11Config to get the tools we need
  find_package(pybind11 REQUIRED CONFIG)
Jason Rhinelander's avatar
Jason Rhinelander committed
76
77
endif()

78
if(NOT CMAKE_BUILD_TYPE AND NOT DEFINED CMAKE_CONFIGURATION_TYPES)
Dean Moldovan's avatar
Dean Moldovan committed
79
  message(STATUS "Setting tests build type to MinSizeRel as none was specified")
Henry Schreiner's avatar
Henry Schreiner committed
80
81
82
83
84
  set(CMAKE_BUILD_TYPE
      MinSizeRel
      CACHE STRING "Choose the type of build." FORCE)
  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel"
                                               "RelWithDebInfo")
Dean Moldovan's avatar
Dean Moldovan committed
85
86
endif()

87
88
89
90
91
92
93
94
if(PYBIND11_CUDA_TESTS)
  enable_language(CUDA)
  if(DEFINED CMAKE_CXX_STANDARD)
    set(CMAKE_CUDA_STANDARD ${CMAKE_CXX_STANDARD})
  endif()
  set(CMAKE_CUDA_STANDARD_REQUIRED ON)
endif()

95
# Full set of test files (you can override these; see below)
Dean Moldovan's avatar
Dean Moldovan committed
96
set(PYBIND11_TEST_FILES
Henry Schreiner's avatar
Henry Schreiner committed
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
    test_async.cpp
    test_buffers.cpp
    test_builtin_casters.cpp
    test_call_policies.cpp
    test_callbacks.cpp
    test_chrono.cpp
    test_class.cpp
    test_constants_and_functions.cpp
    test_copy_move.cpp
    test_custom_type_casters.cpp
    test_docstring_options.cpp
    test_eigen.cpp
    test_enum.cpp
    test_eval.cpp
    test_exceptions.cpp
    test_factory_constructors.cpp
    test_gil_scoped.cpp
    test_iostream.cpp
    test_kwargs_and_defaults.cpp
    test_local_bindings.cpp
    test_methods_and_attributes.cpp
    test_modules.cpp
    test_multiple_inheritance.cpp
    test_numpy_array.cpp
    test_numpy_dtypes.cpp
    test_numpy_vectorize.cpp
    test_opaque_types.cpp
    test_operator_overloading.cpp
    test_pickling.cpp
    test_pytypes.cpp
    test_sequences_and_iterators.cpp
    test_smart_ptr.cpp
    test_stl.cpp
    test_stl_binders.cpp
    test_tagbased_polymorphic.cpp
    test_union.cpp
    test_virtual_functions.cpp)
Dean Moldovan's avatar
Dean Moldovan committed
134

135
# Invoking cmake with something like:
136
#     cmake -DPYBIND11_TEST_OVERRIDE="test_callbacks.cpp;test_pickling.cpp" ..
137
138
# lets you override the tests that get compiled and run.  You can restore to all tests with:
#     cmake -DPYBIND11_TEST_OVERRIDE= ..
Henry Schreiner's avatar
Henry Schreiner committed
139
if(PYBIND11_TEST_OVERRIDE)
140
141
142
  set(PYBIND11_TEST_FILES ${PYBIND11_TEST_OVERRIDE})
endif()

143
144
145
146
147
148
149
150
# You can also filter tests:
if(PYBIND11_TEST_FILTER)
  pybind11_filter_tests(PYBIND11_TEST_FILES ${PYBIND11_TEST_FILTER})
endif()

if(PYTHON_VERSION VERSION_LESS 3.5)
  pybind11_filter_tests(PYBIND11_TEST_FILES test_async.cpp MESSAGE
                        "Skipping test_async on Python 2")
151
152
endif()

153
154
155
# Skip tests for CUDA check:
# /pybind11/tests/test_constants_and_functions.cpp(125):
#   error: incompatible exception specifications
156
157
158
159
if(PYBIND11_CUDA_TESTS)
  pybind11_filter_tests(
    PYBIND11_TEST_FILES test_constants_and_functions.cpp MESSAGE
    "Skipping test_constants_and_functions due to incompatible exception specifications")
160
161
endif()

162
string(REPLACE ".cpp" ".py" PYBIND11_PYTEST_FILES "${PYBIND11_TEST_FILES}")
Dean Moldovan's avatar
Dean Moldovan committed
163

164
165
166
# Contains the set of test files that require pybind11_cross_module_tests to be
# built; if none of these are built (i.e. because TEST_OVERRIDE is used and
# doesn't include them) the second module doesn't get built.
Henry Schreiner's avatar
Henry Schreiner committed
167
168
set(PYBIND11_CROSS_MODULE_TESTS test_exceptions.py test_local_bindings.py test_stl.py
                                test_stl_binders.py)
169

Henry Schreiner's avatar
Henry Schreiner committed
170
set(PYBIND11_CROSS_MODULE_GIL_TESTS test_gil_scoped.py)
171

172
173
174
175
176
# Check if Eigen is available; if not, remove from PYBIND11_TEST_FILES (but
# keep it in PYBIND11_PYTEST_FILES, so that we get the "eigen is not installed"
# skip message).
list(FIND PYBIND11_TEST_FILES test_eigen.cpp PYBIND11_TEST_FILES_EIGEN_I)
if(PYBIND11_TEST_FILES_EIGEN_I GREATER -1)
Jason Rhinelander's avatar
Jason Rhinelander committed
177
178
179
  # Try loading via newer Eigen's Eigen3Config first (bypassing tools/FindEigen3.cmake).
  # Eigen 3.3.1+ exports a cmake 3.0+ target for handling dependency requirements, but also
  # produces a fatal error if loaded from a pre-3.0 cmake.
Henry Schreiner's avatar
Henry Schreiner committed
180
181
182
183
184
  if(DOWNLOAD_EIGEN)
    if(CMAKE_VERSION VERSION_LESS 3.11)
      message(FATAL_ERROR "CMake 3.11+ required when using DOWNLOAD_EIGEN")
    endif()

Henry Schreiner's avatar
Henry Schreiner committed
185
    set(EIGEN3_VERSION_STRING "3.3.8")
Henry Schreiner's avatar
Henry Schreiner committed
186
187
188
189
190

    include(FetchContent)
    FetchContent_Declare(
      eigen
      GIT_REPOSITORY https://gitlab.com/libeigen/eigen.git
Henry Schreiner's avatar
Henry Schreiner committed
191
      GIT_TAG ${EIGEN3_VERSION_STRING})
Henry Schreiner's avatar
Henry Schreiner committed
192
193
194
195
196
197
198
199
200

    FetchContent_GetProperties(eigen)
    if(NOT eigen_POPULATED)
      message(STATUS "Downloading Eigen")
      FetchContent_Populate(eigen)
    endif()

    set(EIGEN3_INCLUDE_DIR ${eigen_SOURCE_DIR})
    set(EIGEN3_FOUND TRUE)
201

Henry Schreiner's avatar
Henry Schreiner committed
202
  else()
203
204
    find_package(Eigen3 3.2.7 QUIET CONFIG)

Henry Schreiner's avatar
Henry Schreiner committed
205
    if(NOT EIGEN3_FOUND)
Henry Schreiner's avatar
Henry Schreiner committed
206
207
208
209
      # Couldn't load via target, so fall back to allowing module mode finding, which will pick up
      # tools/FindEigen3.cmake
      find_package(Eigen3 3.2.7 QUIET)
    endif()
Jason Rhinelander's avatar
Jason Rhinelander committed
210
  endif()
211
212

  if(EIGEN3_FOUND)
213
214
215
216
217
218
    if(NOT TARGET Eigen3::Eigen)
      add_library(Eigen3::Eigen IMPORTED INTERFACE)
      set_property(TARGET Eigen3::Eigen PROPERTY INTERFACE_INCLUDE_DIRECTORIES
                                                 "${EIGEN3_INCLUDE_DIR}")
    endif()

Jason Rhinelander's avatar
Jason Rhinelander committed
219
220
221
222
223
224
    # Eigen 3.3.1+ cmake sets EIGEN3_VERSION_STRING (and hard codes the version when installed
    # rather than looking it up in the cmake script); older versions, and the
    # tools/FindEigen3.cmake, set EIGEN3_VERSION instead.
    if(NOT EIGEN3_VERSION AND EIGEN3_VERSION_STRING)
      set(EIGEN3_VERSION ${EIGEN3_VERSION_STRING})
    endif()
225
226
227
    message(STATUS "Building tests with Eigen v${EIGEN3_VERSION}")
  else()
    list(REMOVE_AT PYBIND11_TEST_FILES ${PYBIND11_TEST_FILES_EIGEN_I})
Henry Schreiner's avatar
Henry Schreiner committed
228
    message(STATUS "Building tests WITHOUT Eigen, use -DDOWNLOAD_EIGEN on CMake 3.11+ to download")
229
  endif()
Dean Moldovan's avatar
Dean Moldovan committed
230
231
endif()

232
233
# Optional dependency for some tests (boost::variant is only supported with version >= 1.56)
find_package(Boost 1.56)
234

235
236
if(Boost_FOUND)
  if(NOT TARGET Boost::headers)
237
    add_library(Boost::headers IMPORTED INTERFACE)
238
239
    if(TARGET Boost::boost)
      # Classic FindBoost
240
      set_property(TARGET Boost::boost PROPERTY INTERFACE_LINK_LIBRARIES Boost::boost)
241
242
243
244
245
246
247
248
    else()
      # Very old FindBoost, or newer Boost than CMake in older CMakes
      set_property(TARGET Boost::headers PROPERTY INTERFACE_INCLUDE_DIRECTORIES
                                                  ${Boost_INCLUDE_DIRS})
    endif()
  endif()
endif()

Jason Rhinelander's avatar
Jason Rhinelander committed
249
250
251
252
# Compile with compiler warnings turned on
function(pybind11_enable_warnings target_name)
  if(MSVC)
    target_compile_options(${target_name} PRIVATE /W4)
253
  elseif(CMAKE_CXX_COMPILER_ID MATCHES "(GNU|Intel|Clang)" AND NOT PYBIND11_CUDA_TESTS)
254
255
256
257
258
259
260
261
262
    target_compile_options(
      ${target_name}
      PRIVATE -Wall
              -Wextra
              -Wconversion
              -Wcast-qual
              -Wdeprecated
              -Wundef
              -Wnon-virtual-dtor)
Jason Rhinelander's avatar
Jason Rhinelander committed
263
264
265
266
267
  endif()

  if(PYBIND11_WERROR)
    if(MSVC)
      target_compile_options(${target_name} PRIVATE /WX)
268
269
    elseif(PYBIND11_CUDA_TESTS)
      target_compile_options(${target_name} PRIVATE "SHELL:-Werror all-warnings")
270
    elseif(CMAKE_CXX_COMPILER_ID MATCHES "(GNU|Intel|Clang)")
Jason Rhinelander's avatar
Jason Rhinelander committed
271
272
273
      target_compile_options(${target_name} PRIVATE -Werror)
    endif()
  endif()
274

275
  # Needs to be readded since the ordering requires these to be after the ones above
Henry Schreiner's avatar
Henry Schreiner committed
276
277
278
  if(CMAKE_CXX_STANDARD
     AND CMAKE_CXX_COMPILER_ID MATCHES "Clang"
     AND PYTHON_VERSION VERSION_LESS 3.0)
279
    if(CMAKE_CXX_STANDARD LESS 17)
280
      target_compile_options(${target_name} PUBLIC -Wno-deprecated-register)
281
    else()
282
283
284
      target_compile_options(${target_name} PUBLIC -Wno-register)
    endif()
  endif()
Jason Rhinelander's avatar
Jason Rhinelander committed
285
286
endfunction()

287
set(test_targets pybind11_tests)
Jason Rhinelander's avatar
Jason Rhinelander committed
288

289
290
291
# Build pybind11_cross_module_tests if any test_whatever.py are being built that require it
foreach(t ${PYBIND11_CROSS_MODULE_TESTS})
  list(FIND PYBIND11_PYTEST_FILES ${t} i)
Henry Schreiner's avatar
Henry Schreiner committed
292
  if(i GREATER -1)
293
294
295
296
    list(APPEND test_targets pybind11_cross_module_tests)
    break()
  endif()
endforeach()
297

298
299
foreach(t ${PYBIND11_CROSS_MODULE_GIL_TESTS})
  list(FIND PYBIND11_PYTEST_FILES ${t} i)
Henry Schreiner's avatar
Henry Schreiner committed
300
  if(i GREATER -1)
301
302
303
304
305
    list(APPEND test_targets cross_module_gil_utils)
    break()
  endif()
endforeach()

306
307
308
309
310
# Support CUDA testing by forcing the target file to compile with NVCC
if(PYBIND11_CUDA_TESTS)
  set_property(SOURCE ${PYBIND11_TEST_FILES} PROPERTY LANGUAGE CUDA)
endif()

311
foreach(target ${test_targets})
312
  set(test_files ${PYBIND11_TEST_FILES})
313
  if(NOT "${target}" STREQUAL "pybind11_tests")
314
315
    set(test_files "")
  endif()
Dean Moldovan's avatar
Dean Moldovan committed
316

317
318
319
320
321
  # Support CUDA testing by forcing the target file to compile with NVCC
  if(PYBIND11_CUDA_TESTS)
    set_property(SOURCE ${target}.cpp PROPERTY LANGUAGE CUDA)
  endif()

322
  # Create the binding library
323
324
  pybind11_add_module(${target} THIN_LTO ${target}.cpp ${test_files} ${PYBIND11_HEADERS})
  pybind11_enable_warnings(${target})
325

326
327
328
329
330
331
332
333
334
335
336
337
  if(NOT CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR)
    get_property(
      suffix
      TARGET ${target}
      PROPERTY SUFFIX)
    set(source_output "${CMAKE_CURRENT_SOURCE_DIR}/${target}${suffix}")
    if(suffix AND EXISTS "${source_output}")
      message(WARNING "Output file also in source directory; "
                      "please remove to avoid confusion: ${source_output}")
    endif()
  endif()

338
  if(MSVC)
339
    target_compile_options(${target} PRIVATE /utf-8)
Jason Rhinelander's avatar
Jason Rhinelander committed
340
  endif()
Dean Moldovan's avatar
Dean Moldovan committed
341

342
  if(EIGEN3_FOUND)
343
    target_link_libraries(${target} PRIVATE Eigen3::Eigen)
344
345
346
347
    target_compile_definitions(${target} PRIVATE -DPYBIND11_TEST_EIGEN)
  endif()

  if(Boost_FOUND)
348
    target_link_libraries(${target} PRIVATE Boost::headers)
349
    target_compile_definitions(${target} PRIVATE -DPYBIND11_TEST_BOOST)
350
  endif()
Dean Moldovan's avatar
Dean Moldovan committed
351

352
353
  # Always write the output file directly into the 'tests' directory (even on MSVC)
  if(NOT CMAKE_LIBRARY_OUTPUT_DIRECTORY)
354
355
    set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY
                                               "${CMAKE_CURRENT_BINARY_DIR}")
356
357
358
359
360
361
362
363

    if(DEFINED CMAKE_CONFIGURATION_TYPES)
      foreach(config ${CMAKE_CONFIGURATION_TYPES})
        string(TOUPPER ${config} config)
        set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY_${config}
                                                   "${CMAKE_CURRENT_BINARY_DIR}")
      endforeach()
    endif()
364
365
  endif()
endforeach()
Dean Moldovan's avatar
Dean Moldovan committed
366

367
# Make sure pytest is found or produce a warning
368
pybind11_find_import(pytest VERSION 3.1)
369

370
371
372
373
374
375
376
377
378
379
380
if(NOT CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR)
  # This is not used later in the build, so it's okay to regenerate each time.
  configure_file("${CMAKE_CURRENT_SOURCE_DIR}/pytest.ini" "${CMAKE_CURRENT_BINARY_DIR}/pytest.ini"
                 COPYONLY)
  file(APPEND "${CMAKE_CURRENT_BINARY_DIR}/pytest.ini"
       "\ntestpaths = \"${CMAKE_CURRENT_SOURCE_DIR}\"")

endif()

# cmake 3.12 added list(transform <list> prepend
# but we can't use it yet
381
string(REPLACE "test_" "${CMAKE_CURRENT_SOURCE_DIR}/test_" PYBIND11_ABS_PYTEST_FILES
382
383
               "${PYBIND11_PYTEST_FILES}")

384
385
386
387
set(PYBIND11_TEST_PREFIX_COMMAND
    ""
    CACHE STRING "Put this before pytest, use for checkers and such")

Dean Moldovan's avatar
Dean Moldovan committed
388
# A single command to compile and run the tests
Henry Schreiner's avatar
Henry Schreiner committed
389
390
add_custom_target(
  pytest
391
392
  COMMAND ${PYBIND11_TEST_PREFIX_COMMAND} ${PYTHON_EXECUTABLE} -m pytest
          ${PYBIND11_ABS_PYTEST_FILES}
Henry Schreiner's avatar
Henry Schreiner committed
393
  DEPENDS ${test_targets}
394
  WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}"
Henry Schreiner's avatar
Henry Schreiner committed
395
  USES_TERMINAL)
396

397
if(PYBIND11_TEST_OVERRIDE)
Henry Schreiner's avatar
Henry Schreiner committed
398
399
400
401
402
  add_custom_command(
    TARGET pytest
    POST_BUILD
    COMMAND ${CMAKE_COMMAND} -E echo
            "Note: not all tests run: -DPYBIND11_TEST_OVERRIDE is in effect")
403
404
endif()

405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
# cmake-format: off
add_custom_target(
  memcheck
  COMMAND
    PYTHONMALLOC=malloc
    valgrind
    --leak-check=full
    --show-leak-kinds=definite,indirect
    --errors-for-leak-kinds=definite,indirect
    --error-exitcode=1
    --read-var-info=yes
    --track-origins=yes
    --suppressions="${CMAKE_CURRENT_SOURCE_DIR}/valgrind-python.supp"
    --suppressions="${CMAKE_CURRENT_SOURCE_DIR}/valgrind-numpy-scipy.supp"
    --gen-suppressions=all
    ${PYTHON_EXECUTABLE} -m pytest ${PYBIND11_ABS_PYTEST_FILES}
  DEPENDS ${test_targets}
  WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}"
  USES_TERMINAL)
# cmake-format: on

Jason Rhinelander's avatar
Jason Rhinelander committed
426
427
428
429
430
# Add a check target to run all the tests, starting with pytest (we add dependencies to this below)
add_custom_target(check DEPENDS pytest)

# The remaining tests only apply when being built as part of the pybind11 project, but not if the
# tests are being built independently.
431
if(CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_SOURCE_DIR)
Jason Rhinelander's avatar
Jason Rhinelander committed
432
433
434
  return()
endif()

435
# Add a post-build comment to show the primary test suite .so size and, if a previous size, compare it:
436
add_custom_command(
Henry Schreiner's avatar
Henry Schreiner committed
437
438
439
440
  TARGET pybind11_tests
  POST_BUILD
  COMMAND
    ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/../tools/libsize.py
441
442
    $<TARGET_FILE:pybind11_tests>
    ${CMAKE_CURRENT_BINARY_DIR}/sosize-$<TARGET_FILE_NAME:pybind11_tests>.txt)
443

444
445
446
if(NOT PYBIND11_CUDA_TESTS)
  # Test embedding the interpreter. Provides the `cpptest` target.
  add_subdirectory(test_embed)
447

448
449
450
  # Test CMake build using functions and targets from subdirectory or installed location
  add_subdirectory(test_cmake_build)
endif()