CMakeLists.txt 9.4 KB
Newer Older
Jason Rhinelander's avatar
Jason Rhinelander committed
1
2
3
4
5
6
7
8
9
10
# CMakeLists.txt -- Build system for the pybind11 test suite
#
# Copyright (c) 2015 Wenzel Jakob <wenzel@inf.ethz.ch>
#
# All rights reserved. Use of this source code is governed by a
# BSD-style license that can be found in the LICENSE file.

cmake_minimum_required(VERSION 2.8.12)

option(PYBIND11_WERROR  "Report all warnings as errors"  OFF)
11
set(PYBIND11_TEST_OVERRIDE "" CACHE STRING "Tests from ;-separated list of *.cpp files will be built instead of all tests")
Jason Rhinelander's avatar
Jason Rhinelander committed
12
13
14
15

if (CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_SOURCE_DIR)
    # We're being loaded directly, i.e. not via add_subdirectory, so make this
    # work as its own project and load the pybind11Config to get the tools we need
16
    project(pybind11_tests CXX)
Jason Rhinelander's avatar
Jason Rhinelander committed
17
18
19
20

    find_package(pybind11 REQUIRED CONFIG)
endif()

Dean Moldovan's avatar
Dean Moldovan committed
21
22
if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  message(STATUS "Setting tests build type to MinSizeRel as none was specified")
23
24
25
  set(CMAKE_BUILD_TYPE MinSizeRel CACHE STRING "Choose the type of build." FORCE)
  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
    "MinSizeRel" "RelWithDebInfo")
Dean Moldovan's avatar
Dean Moldovan committed
26
27
endif()

28
# Full set of test files (you can override these; see below)
Dean Moldovan's avatar
Dean Moldovan committed
29
set(PYBIND11_TEST_FILES
30
  test_async.cpp
Dean Moldovan's avatar
Dean Moldovan committed
31
  test_buffers.cpp
32
  test_builtin_casters.cpp
Dean Moldovan's avatar
Dean Moldovan committed
33
  test_call_policies.cpp
Dean Moldovan's avatar
Dean Moldovan committed
34
  test_callbacks.cpp
35
  test_chrono.cpp
36
  test_class.cpp
Dean Moldovan's avatar
Dean Moldovan committed
37
  test_constants_and_functions.cpp
38
  test_copy_move.cpp
39
  test_docstring_options.cpp
40
  test_eigen.cpp
41
  test_enum.cpp
Dean Moldovan's avatar
Dean Moldovan committed
42
43
  test_eval.cpp
  test_exceptions.cpp
44
  test_factory_constructors.cpp
45
  test_gil_scoped.cpp
46
  test_iostream.cpp
Dean Moldovan's avatar
Dean Moldovan committed
47
  test_kwargs_and_defaults.cpp
48
  test_local_bindings.cpp
Dean Moldovan's avatar
Dean Moldovan committed
49
50
  test_methods_and_attributes.cpp
  test_modules.cpp
Dean Moldovan's avatar
Dean Moldovan committed
51
  test_multiple_inheritance.cpp
52
  test_numpy_array.cpp
Dean Moldovan's avatar
Dean Moldovan committed
53
54
55
56
57
  test_numpy_dtypes.cpp
  test_numpy_vectorize.cpp
  test_opaque_types.cpp
  test_operator_overloading.cpp
  test_pickling.cpp
58
  test_pytypes.cpp
Dean Moldovan's avatar
Dean Moldovan committed
59
  test_sequences_and_iterators.cpp
Dean Moldovan's avatar
Dean Moldovan committed
60
  test_smart_ptr.cpp
61
  test_stl.cpp
Dean Moldovan's avatar
Dean Moldovan committed
62
  test_stl_binders.cpp
63
  test_tagbased_polymorphic.cpp
64
  test_union.cpp
Dean Moldovan's avatar
Dean Moldovan committed
65
66
67
  test_virtual_functions.cpp
)

68
# Invoking cmake with something like:
69
#     cmake -DPYBIND11_TEST_OVERRIDE="test_callbacks.cpp;test_picking.cpp" ..
70
71
72
73
74
75
# lets you override the tests that get compiled and run.  You can restore to all tests with:
#     cmake -DPYBIND11_TEST_OVERRIDE= ..
if (PYBIND11_TEST_OVERRIDE)
  set(PYBIND11_TEST_FILES ${PYBIND11_TEST_OVERRIDE})
endif()

76
77
78
79
80
81
82
# Skip test_async for Python < 3.5
list(FIND PYBIND11_TEST_FILES test_async.cpp PYBIND11_TEST_FILES_ASYNC_I)
if((PYBIND11_TEST_FILES_ASYNC_I GREATER -1) AND ("${PYTHON_VERSION_MAJOR}.${PYTHON_VERSION_MINOR}" VERSION_LESS 3.5))
  message(STATUS "Skipping test_async because Python version ${PYTHON_VERSION_MAJOR}.${PYTHON_VERSION_MINOR} < 3.5")
  list(REMOVE_AT PYBIND11_TEST_FILES ${PYBIND11_TEST_FILES_ASYNC_I})
endif()

83
string(REPLACE ".cpp" ".py" PYBIND11_PYTEST_FILES "${PYBIND11_TEST_FILES}")
Dean Moldovan's avatar
Dean Moldovan committed
84

85
86
87
88
# Contains the set of test files that require pybind11_cross_module_tests to be
# built; if none of these are built (i.e. because TEST_OVERRIDE is used and
# doesn't include them) the second module doesn't get built.
set(PYBIND11_CROSS_MODULE_TESTS
89
  test_exceptions.py
90
  test_local_bindings.py
91
  test_stl.py
92
  test_stl_binders.py
93
94
)

95
96
97
98
set(PYBIND11_CROSS_MODULE_GIL_TESTS
  test_gil_scoped.py
)

99
100
101
102
103
# Check if Eigen is available; if not, remove from PYBIND11_TEST_FILES (but
# keep it in PYBIND11_PYTEST_FILES, so that we get the "eigen is not installed"
# skip message).
list(FIND PYBIND11_TEST_FILES test_eigen.cpp PYBIND11_TEST_FILES_EIGEN_I)
if(PYBIND11_TEST_FILES_EIGEN_I GREATER -1)
Jason Rhinelander's avatar
Jason Rhinelander committed
104
105
106
107
  # Try loading via newer Eigen's Eigen3Config first (bypassing tools/FindEigen3.cmake).
  # Eigen 3.3.1+ exports a cmake 3.0+ target for handling dependency requirements, but also
  # produces a fatal error if loaded from a pre-3.0 cmake.
  if (NOT CMAKE_VERSION VERSION_LESS 3.0)
108
    find_package(Eigen3 3.2.7 QUIET CONFIG)
Jason Rhinelander's avatar
Jason Rhinelander committed
109
110
111
112
113
114
115
116
117
    if (EIGEN3_FOUND)
      if (EIGEN3_VERSION_STRING AND NOT EIGEN3_VERSION_STRING VERSION_LESS 3.3.1)
        set(PYBIND11_EIGEN_VIA_TARGET 1)
      endif()
    endif()
  endif()
  if (NOT EIGEN3_FOUND)
    # Couldn't load via target, so fall back to allowing module mode finding, which will pick up
    # tools/FindEigen3.cmake
118
    find_package(Eigen3 3.2.7 QUIET)
Jason Rhinelander's avatar
Jason Rhinelander committed
119
  endif()
120
121

  if(EIGEN3_FOUND)
Jason Rhinelander's avatar
Jason Rhinelander committed
122
123
124
125
126
127
    # Eigen 3.3.1+ cmake sets EIGEN3_VERSION_STRING (and hard codes the version when installed
    # rather than looking it up in the cmake script); older versions, and the
    # tools/FindEigen3.cmake, set EIGEN3_VERSION instead.
    if(NOT EIGEN3_VERSION AND EIGEN3_VERSION_STRING)
      set(EIGEN3_VERSION ${EIGEN3_VERSION_STRING})
    endif()
128
129
130
131
132
    message(STATUS "Building tests with Eigen v${EIGEN3_VERSION}")
  else()
    list(REMOVE_AT PYBIND11_TEST_FILES ${PYBIND11_TEST_FILES_EIGEN_I})
    message(STATUS "Building tests WITHOUT Eigen")
  endif()
Dean Moldovan's avatar
Dean Moldovan committed
133
134
endif()

135
136
# Optional dependency for some tests (boost::variant is only supported with version >= 1.56)
find_package(Boost 1.56)
137

Jason Rhinelander's avatar
Jason Rhinelander committed
138
139
140
141
# Compile with compiler warnings turned on
function(pybind11_enable_warnings target_name)
  if(MSVC)
    target_compile_options(${target_name} PRIVATE /W4)
142
  elseif(CMAKE_CXX_COMPILER_ID MATCHES "(GNU|Intel|Clang)")
143
      target_compile_options(${target_name} PRIVATE -Wall -Wextra -Wconversion -Wcast-qual -Wdeprecated)
Jason Rhinelander's avatar
Jason Rhinelander committed
144
145
146
147
148
  endif()

  if(PYBIND11_WERROR)
    if(MSVC)
      target_compile_options(${target_name} PRIVATE /WX)
149
    elseif(CMAKE_CXX_COMPILER_ID MATCHES "(GNU|Intel|Clang)")
Jason Rhinelander's avatar
Jason Rhinelander committed
150
151
152
153
154
      target_compile_options(${target_name} PRIVATE -Werror)
    endif()
  endif()
endfunction()

155
set(test_targets pybind11_tests)
Jason Rhinelander's avatar
Jason Rhinelander committed
156

157
158
159
160
161
162
163
164
# Build pybind11_cross_module_tests if any test_whatever.py are being built that require it
foreach(t ${PYBIND11_CROSS_MODULE_TESTS})
  list(FIND PYBIND11_PYTEST_FILES ${t} i)
  if (i GREATER -1)
    list(APPEND test_targets pybind11_cross_module_tests)
    break()
  endif()
endforeach()
165

166
167
168
169
170
171
172
173
foreach(t ${PYBIND11_CROSS_MODULE_GIL_TESTS})
  list(FIND PYBIND11_PYTEST_FILES ${t} i)
  if (i GREATER -1)
    list(APPEND test_targets cross_module_gil_utils)
    break()
  endif()
endforeach()

174
set(testdir ${CMAKE_CURRENT_SOURCE_DIR})
175
foreach(target ${test_targets})
176
  set(test_files ${PYBIND11_TEST_FILES})
177
  if(NOT target STREQUAL "pybind11_tests")
178
179
    set(test_files "")
  endif()
Dean Moldovan's avatar
Dean Moldovan committed
180

181
  # Create the binding library
182
183
  pybind11_add_module(${target} THIN_LTO ${target}.cpp ${test_files} ${PYBIND11_HEADERS})
  pybind11_enable_warnings(${target})
184
185

  if(MSVC)
186
    target_compile_options(${target} PRIVATE /utf-8)
Jason Rhinelander's avatar
Jason Rhinelander committed
187
  endif()
Dean Moldovan's avatar
Dean Moldovan committed
188

189
190
  if(EIGEN3_FOUND)
    if (PYBIND11_EIGEN_VIA_TARGET)
191
      target_link_libraries(${target} PRIVATE Eigen3::Eigen)
192
    else()
193
      target_include_directories(${target} PRIVATE ${EIGEN3_INCLUDE_DIR})
194
    endif()
195
196
197
198
199
200
    target_compile_definitions(${target} PRIVATE -DPYBIND11_TEST_EIGEN)
  endif()

  if(Boost_FOUND)
    target_include_directories(${target} PRIVATE ${Boost_INCLUDE_DIRS})
    target_compile_definitions(${target} PRIVATE -DPYBIND11_TEST_BOOST)
201
  endif()
Dean Moldovan's avatar
Dean Moldovan committed
202

203
204
  # Always write the output file directly into the 'tests' directory (even on MSVC)
  if(NOT CMAKE_LIBRARY_OUTPUT_DIRECTORY)
205
    set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${testdir})
206
207
    foreach(config ${CMAKE_CONFIGURATION_TYPES})
      string(TOUPPER ${config} config)
208
      set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY_${config} ${testdir})
209
210
211
    endforeach()
  endif()
endforeach()
Dean Moldovan's avatar
Dean Moldovan committed
212

213
# Make sure pytest is found or produce a fatal error
214
if(NOT PYBIND11_PYTEST_FOUND)
215
216
217
218
219
220
221
222
  execute_process(COMMAND ${PYTHON_EXECUTABLE} -c "import pytest; print(pytest.__version__)"
                  RESULT_VARIABLE pytest_not_found OUTPUT_VARIABLE pytest_version ERROR_QUIET)
  if(pytest_not_found)
    message(FATAL_ERROR "Running the tests requires pytest. Please install it manually"
                        " (try: ${PYTHON_EXECUTABLE} -m pip install pytest)")
  elseif(pytest_version VERSION_LESS 3.0)
    message(FATAL_ERROR "Running the tests requires pytest >= 3.0. Found: ${pytest_version}"
                        "Please update it (try: ${PYTHON_EXECUTABLE} -m pip install -U pytest)")
223
  endif()
Wenzel Jakob's avatar
Wenzel Jakob committed
224
  set(PYBIND11_PYTEST_FOUND TRUE CACHE INTERNAL "")
225
226
endif()

227
228
229
230
231
232
if(CMAKE_VERSION VERSION_LESS 3.2)
  set(PYBIND11_USES_TERMINAL "")
else()
  set(PYBIND11_USES_TERMINAL "USES_TERMINAL")
endif()

Dean Moldovan's avatar
Dean Moldovan committed
233
# A single command to compile and run the tests
234
add_custom_target(pytest COMMAND ${PYTHON_EXECUTABLE} -m pytest ${PYBIND11_PYTEST_FILES}
235
                  DEPENDS ${test_targets} WORKING_DIRECTORY ${testdir} ${PYBIND11_USES_TERMINAL})
236

237
238
239
240
241
if(PYBIND11_TEST_OVERRIDE)
  add_custom_command(TARGET pytest POST_BUILD
    COMMAND ${CMAKE_COMMAND} -E echo "Note: not all tests run: -DPYBIND11_TEST_OVERRIDE is in effect")
endif()

Jason Rhinelander's avatar
Jason Rhinelander committed
242
243
244
245
246
247
248
249
250
# Add a check target to run all the tests, starting with pytest (we add dependencies to this below)
add_custom_target(check DEPENDS pytest)

# The remaining tests only apply when being built as part of the pybind11 project, but not if the
# tests are being built independently.
if (NOT PROJECT_NAME STREQUAL "pybind11")
  return()
endif()

251
# Add a post-build comment to show the primary test suite .so size and, if a previous size, compare it:
252
add_custom_command(TARGET pybind11_tests POST_BUILD
253
  COMMAND ${PYTHON_EXECUTABLE} ${PROJECT_SOURCE_DIR}/tools/libsize.py
254
255
  $<TARGET_FILE:pybind11_tests> ${CMAKE_CURRENT_BINARY_DIR}/sosize-$<TARGET_FILE_NAME:pybind11_tests>.txt)

256
257
258
# Test embedding the interpreter. Provides the `cpptest` target.
add_subdirectory(test_embed)

259
# Test CMake build using functions and targets from subdirectory or installed location
260
add_subdirectory(test_cmake_build)