Use pre-built binaries for ffmpeg extension (#3460)

Summary:
This commit changes the way FFmpeg extension is built.

Originally, the build process expected the FFmpeg binaries to be somehow available in build env.
This makes the build process unpredictable and prevents default enabling FFmpeg extension.

The proposed change uses pre-built FFmpeg binaries as build-time only scaffold, which are built in our CI job https://github.com/pytorch/audio/actions/workflows/ffmpeg.yml.

This makes the build process more predictable and removes the necessity to build FFmpeg in our CI.
Currently, it supports macOS (arm64, x86_64), unix (x86_64, aarch64) and windows (amd64).
The downside is that it no longer works with the architecture not listed above.
We can potentially workaround by searching the FFmpeg binaries available in system (the old way) for
these system, but since they are not supported by PyTorch, the priority is low.

Pull Request resolved: https://github.com/pytorch/audio/pull/3460

Differential Revision: D47261885

Pulled By: mthrok

fbshipit-source-id: 223a15e95c9140c95688af968beb35ff40354476

CMakeLists.txt

@@ -171,6 +171,7 @@ if (BUILD_SOX)
   add_subdirectory(torchaudio/csrc/sox)
 endif()
 if (USE_FFMPEG)
+  add_subdirectory(third_party/ffmpeg)
   add_subdirectory(torchaudio/csrc/ffmpeg)
 endif()
 if (BUILD_CUDA_CTC_DECODER)

cmake/FindFFMPEG.cmake

-#[==[
-
-Originally taken from: https://github.com/Kitware/VTK/blob/8485477f9aa41f3c33094c3beb201e747abf5541/CMake/FindFFMPEG.cmake
-License: https://github.com/Kitware/VTK/blob/8485477f9aa41f3c33094c3beb201e747abf5541/Copyright.txt
-
-/*=========================================================================
-
-  Program:   Visualization Toolkit
-  Module:    Copyright.txt
-
-Copyright (c) 1993-2015 Ken Martin, Will Schroeder, Bill Lorensen
-All rights reserved.
-
-Redistribution and use in source and binary forms, with or without
-modification, are permitted provided that the following conditions are met:
-
- * Redistributions of source code must retain the above copyright notice,
-   this list of conditions and the following disclaimer.
-
- * Redistributions in binary form must reproduce the above copyright notice,
-   this list of conditions and the following disclaimer in the documentation
-   and/or other materials provided with the distribution.
-
- * Neither name of Ken Martin, Will Schroeder, or Bill Lorensen nor the names
-   of any contributors may be used to endorse or promote products derived
-   from this software without specific prior written permission.
-
-THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS ``AS IS''
-AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
-IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
-ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHORS OR CONTRIBUTORS BE LIABLE FOR
-ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
-DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
-SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
-CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
-OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
-OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
-
-=========================================================================*/
-
-=========================================================================
- 
-Provides the following variables:
-
-  * `FFMPEG_INCLUDE_DIRS`: Include directories necessary to use FFMPEG.
-  * `FFMPEG_LIBRARIES`: Libraries necessary to use FFMPEG. Note that this only
-    includes libraries for the components requested.
-  * `FFMPEG_VERSION`: The version of FFMPEG found.
-
-The following components are supported:
-
-  * `avcodec`
-  * `avdevice`
-  * `avfilter`
-  * `avformat`
-  * `avutil`
-  * `swresample`
-  * `swscale`
-
-For each component, the following are provided:
-
-  * `FFMPEG_<component>_FOUND`: Libraries for the component.
-  * `FFMPEG_<component>_INCLUDE_DIRS`: Include directories for
-    the component.
-  * `FFMPEG_<component>_LIBRARIES`: Libraries for the component.
-  * `FFMPEG::<component>`: A target to use with `target_link_libraries`.
-
-Note that only components requested with `COMPONENTS` or `OPTIONAL_COMPONENTS`
-are guaranteed to set these variables or provide targets.
-#]==]
-
-function (_ffmpeg_find component headername)
-  find_path("FFMPEG_${component}_INCLUDE_DIR"
-    NAMES
-      "lib${component}/${headername}"
-    PATHS
-      "$ENV{FFMPEG_ROOT}/include"
-    PATH_SUFFIXES
-      ffmpeg
-    DOC "FFMPEG's ${component} include directory"
-    NO_DEFAULT_PATH)
-  find_path("FFMPEG_${component}_INCLUDE_DIR"
-    NAMES
-      "lib${component}/${headername}"
-    PATHS
-      "$ENV{CONDA_PREFIX}/include"
-    PATH_SUFFIXES
-      ffmpeg
-    DOC "FFMPEG's ${component} include directory"
-    NO_DEFAULT_PATH)
-  find_path("FFMPEG_${component}_INCLUDE_DIR"
-    NAMES
-      "lib${component}/${headername}"
-    PATHS
-      ~/Library/Frameworks
-      /Library/Frameworks
-      /usr/local/include
-      /usr/include
-      /sw/include # Fink
-      /opt/local/include # DarwinPorts
-      /opt/csw/include # Blastwave
-      /opt/include
-      /usr/freeware/include
-    PATH_SUFFIXES
-      ffmpeg
-    DOC "FFMPEG's ${component} include directory")
-  mark_as_advanced("FFMPEG_${component}_INCLUDE_DIR")
-
-  # On Windows, static FFMPEG is sometimes built as `lib<name>.a`.
-  if (WIN32)
-    list(APPEND CMAKE_FIND_LIBRARY_SUFFIXES ".a" ".lib")
-    list(APPEND CMAKE_FIND_LIBRARY_PREFIXES "" "lib")
-  endif ()
-
-  find_library("FFMPEG_${component}_LIBRARY"
-    NAMES
-      "${component}"
-    PATHS
-      "$ENV{FFMPEG_ROOT}/lib"
-      "$ENV{FFMPEG_ROOT}/bin"
-    DOC "FFMPEG's ${component} library"
-    NO_DEFAULT_PATH)
-  find_library("FFMPEG_${component}_LIBRARY"
-    NAMES
-      "${component}"
-    PATHS
-      "$ENV{CONDA_PREFIX}/lib"
-      "$ENV{CONDA_PREFIX}/bin"
-    DOC "FFMPEG's ${component} library"
-    NO_DEFAULT_PATH)
-  find_library("FFMPEG_${component}_LIBRARY"
-    NAMES
-      "${component}"
-    PATHS
-      ~/Library/Frameworks
-      /Library/Frameworks
-      /usr/local/lib
-      /usr/local/lib64
-      /usr/lib
-      /usr/lib64
-      /sw/lib
-      /opt/local/lib
-      /opt/csw/lib
-      /opt/lib
-      /usr/freeware/lib64
-    DOC "FFMPEG's ${component} library")
-  mark_as_advanced("FFMPEG_${component}_LIBRARY")
-
-  if (FFMPEG_${component}_LIBRARY AND FFMPEG_${component}_INCLUDE_DIR)
-    set(_deps_found TRUE)
-    set(_deps_link)
-    foreach (_ffmpeg_dep IN LISTS ARGN)
-      if (TARGET "FFMPEG::${_ffmpeg_dep}")
-        list(APPEND _deps_link "FFMPEG::${_ffmpeg_dep}")
-      else ()
-        set(_deps_found FALSE)
-      endif ()
-    endforeach ()
-    if (_deps_found)
-      if (NOT TARGET "FFMPEG::${component}")
-        add_library("FFMPEG::${component}" UNKNOWN IMPORTED)
-        set_target_properties("FFMPEG::${component}" PROPERTIES
-          IMPORTED_LOCATION "${FFMPEG_${component}_LIBRARY}"
-          INTERFACE_INCLUDE_DIRECTORIES "${FFMPEG_${component}_INCLUDE_DIR}"
-          IMPORTED_LINK_INTERFACE_LIBRARIES "${_deps_link}")
-      endif ()
-      set("FFMPEG_${component}_FOUND" 1
-        PARENT_SCOPE)
-
-      set(version_header_path "${FFMPEG_${component}_INCLUDE_DIR}/lib${component}/version.h")
-      if (EXISTS "${version_header_path}")
-        string(TOUPPER "${component}" component_upper)
-        file(STRINGS "${version_header_path}" version
-          REGEX "#define  *LIB${component_upper}_VERSION_(MAJOR|MINOR|MICRO) ")
-        string(REGEX REPLACE ".*_MAJOR *\([0-9]*\).*" "\\1" major "${version}")
-        string(REGEX REPLACE ".*_MINOR *\([0-9]*\).*" "\\1" minor "${version}")
-        string(REGEX REPLACE ".*_MICRO *\([0-9]*\).*" "\\1" micro "${version}")
-        if (NOT major STREQUAL "" AND
-            NOT minor STREQUAL "" AND
-            NOT micro STREQUAL "")
-          set("FFMPEG_${component}_VERSION" "${major}.${minor}.${micro}"
-            PARENT_SCOPE)
-        endif ()
-      endif ()
-    else ()
-      set("FFMPEG_${component}_FOUND" 0
-        PARENT_SCOPE)
-      set(what)
-      if (NOT FFMPEG_${component}_LIBRARY)
-        set(what "library")
-      endif ()
-      if (NOT FFMPEG_${component}_INCLUDE_DIR)
-        if (what)
-          string(APPEND what " or headers")
-        else ()
-          set(what "headers")
-        endif ()
-      endif ()
-      set("FFMPEG_${component}_NOT_FOUND_MESSAGE"
-        "Could not find the ${what} for ${component}."
-        PARENT_SCOPE)
-    endif ()
-  endif ()
-endfunction ()
-
-_ffmpeg_find(avutil     avutil.h)
-_ffmpeg_find(swresample swresample.h
-  avutil)
-_ffmpeg_find(swscale    swscale.h
-  avutil)
-_ffmpeg_find(avcodec    avcodec.h
-  avutil)
-_ffmpeg_find(avformat   avformat.h
-  avcodec avutil)
-_ffmpeg_find(avfilter   avfilter.h
-  avutil)
-_ffmpeg_find(avdevice   avdevice.h
-  avformat avutil)
-
-if (TARGET FFMPEG::avutil)
-  set(_ffmpeg_version_header_path "${FFMPEG_avutil_INCLUDE_DIR}/libavutil/ffversion.h")
-  if (EXISTS "${_ffmpeg_version_header_path}")
-    file(STRINGS "${_ffmpeg_version_header_path}" _ffmpeg_version
-      REGEX "FFMPEG_VERSION")
-    string(REGEX REPLACE ".*\"n?\(.*\)\"" "\\1" FFMPEG_VERSION "${_ffmpeg_version}")
-    unset(_ffmpeg_version)
-  else ()
-    set(FFMPEG_VERSION FFMPEG_VERSION-NOTFOUND)
-  endif ()
-  unset(_ffmpeg_version_header_path)
-endif ()
-
-set(FFMPEG_INCLUDE_DIRS)
-set(FFMPEG_LIBRARIES)
-set(_ffmpeg_required_vars)
-foreach (_ffmpeg_component IN LISTS FFMPEG_FIND_COMPONENTS)
-  if (TARGET "FFMPEG::${_ffmpeg_component}")
-    set(FFMPEG_${_ffmpeg_component}_INCLUDE_DIRS
-      "${FFMPEG_${_ffmpeg_component}_INCLUDE_DIR}")
-    set(FFMPEG_${_ffmpeg_component}_LIBRARIES
-      "${FFMPEG_${_ffmpeg_component}_LIBRARY}")
-    list(APPEND FFMPEG_INCLUDE_DIRS
-      "${FFMPEG_${_ffmpeg_component}_INCLUDE_DIRS}")
-    list(APPEND FFMPEG_LIBRARIES
-      "${FFMPEG_${_ffmpeg_component}_LIBRARIES}")
-    if (FFMEG_FIND_REQUIRED_${_ffmpeg_component})
-      list(APPEND _ffmpeg_required_vars
-        "FFMPEG_${_ffmpeg_required_vars}_INCLUDE_DIRS"
-        "FFMPEG_${_ffmpeg_required_vars}_LIBRARIES")
-    endif ()
-  endif ()
-endforeach ()
-unset(_ffmpeg_component)
-
-if (FFMPEG_INCLUDE_DIRS)
-  list(REMOVE_DUPLICATES FFMPEG_INCLUDE_DIRS)
-endif ()
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(FFMPEG
-  REQUIRED_VARS FFMPEG_INCLUDE_DIRS FFMPEG_LIBRARIES ${_ffmpeg_required_vars}
-  VERSION_VAR FFMPEG_VERSION
-  HANDLE_COMPONENTS)
-unset(_ffmpeg_required_vars)

third_party/ffmpeg/CMakeLists.txt

+################################################################################
+# This file defines the following FFmpeg libraries using pre-built binaries.
+
+add_library(ffmpeg4 INTERFACE)
+add_library(ffmpeg ALIAS ffmpeg4)
+
+################################################################################
+
+include(FetchContent)
+
+set(base_url https://pytorch.s3.amazonaws.com/torchaudio/ffmpeg)
+
+if (APPLE)
+  if ("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "arm64")
+    FetchContent_Declare(
+      f4
+      URL ${base_url}/2023-07-06/macos_arm64/4.1.8.tar.gz
+      URL_HASH SHA256=a44b8152b7f204ce5050fc7f6fd2bbbafe7ae4e45f03e135f3b45dd9a08f404e
+      )
+  elseif ("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "x86_64")
+    FetchContent_Declare(
+      f4
+      URL ${base_url}/2023-07-06/macos_x86_64/4.1.8.tar.gz
+      URL_HASH SHA256=392d5af0b24535bfc69d6244e7595e5f07117b93d94505d0a4b34c82ae479f48
+      )
+  else ()
+    message(
+      FATAL_ERROR
+      "CPU architecture ${CMAKE_SYSTEM_PROCESSOR} is not currently supported. If you do not need FFmpeg integration, then setting USE_FFMPEG=0 will bypass the issue.")
+  endif()
+elseif (UNIX)
+  if ("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "aarch64")
+    FetchContent_Declare(
+      f4
+      URL ${base_url}/2023-07-06/linux_aarch64/4.1.8.tar.gz
+      URL_HASH SHA256=aae0b713040e30ceebe0d0bc82353d3d9054055c7af8a4f4abc1766015ab7681
+    )
+  elseif ("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "x86_64")
+    FetchContent_Declare(
+      f4
+      URL ${base_url}/2023-07-06/linux_x86_64/4.1.8.tar.gz
+      URL_HASH SHA256=52e53b8857739bdd54f9d8541e22569b57f6c6f16504ee83963c2ed3e7061a23
+      )
+  else ()
+    # Possible case ppc64le (though it's not officially supported.)
+    message(
+      FATAL_ERROR
+      "CPU architecture ${CMAKE_SYSTEM_PROCESSOR} is not currently supported. If you do not need FFmpeg integration, then setting USE_FFMPEG=0 will bypass the issue.")
+  endif()
+elseif(MSVC)
+  FetchContent_Declare(
+    f4
+    URL ${base_url}/2023-07-06/windows/4.1.8.tar.gz
+    URL_HASH SHA256=c45cd36e0575490f97ace07365bb67c5e1cbe9f3e6a4272d035c19348df96790
+    )
+endif()
+
+FetchContent_MakeAvailable(f4)
+target_include_directories(ffmpeg4 INTERFACE ${f4_SOURCE_DIR}/include)
+
+if(APPLE)
+  target_link_libraries(
+    ffmpeg4
+    INTERFACE
+    ${f4_SOURCE_DIR}/lib/libavutil.56.dylib
+    ${f4_SOURCE_DIR}/lib/libavcodec.58.dylib
+    ${f4_SOURCE_DIR}/lib/libavformat.58.dylib
+    ${f4_SOURCE_DIR}/lib/libavdevice.58.dylib
+    ${f4_SOURCE_DIR}/lib/libavfilter.7.dylib
+    )
+elseif (UNIX)
+  target_link_libraries(
+    ffmpeg4
+    INTERFACE
+    ${f4_SOURCE_DIR}/lib/libavutil.so.56
+    ${f4_SOURCE_DIR}/lib/libavcodec.so.58
+    ${f4_SOURCE_DIR}/lib/libavformat.so.58
+    ${f4_SOURCE_DIR}/lib/libavdevice.so.58
+    ${f4_SOURCE_DIR}/lib/libavfilter.so.7
+    )
+elseif(MSVC)
+  target_link_libraries(
+    ffmpeg4
+    INTERFACE
+    ${f4_SOURCE_DIR}/bin/avutil.lib
+    ${f4_SOURCE_DIR}/bin/avcodec.lib
+    ${f4_SOURCE_DIR}/bin/avformat.lib
+    ${f4_SOURCE_DIR}/bin/avdevice.lib
+    ${f4_SOURCE_DIR}/bin/avfilter.lib
+    )
+endif()

tools/setup_helpers/extension.py

@@ -36,7 +36,7 @@ def _get_build(var, default=False):
 _BUILD_SOX = False if platform.system() == "Windows" else _get_build("BUILD_SOX", True)
 _BUILD_RIR = _get_build("BUILD_RIR", True)
 _BUILD_RNNT = _get_build("BUILD_RNNT", True)
-_USE_FFMPEG = _get_build("USE_FFMPEG", False)
+_USE_FFMPEG = _get_build("USE_FFMPEG", True)
 _USE_ROCM = _get_build("USE_ROCM", torch.backends.cuda.is_built() and torch.version.hip is not None)
 _USE_CUDA = _get_build("USE_CUDA", torch.backends.cuda.is_built() and torch.version.hip is None)
 _BUILD_ALIGN = _get_build("BUILD_ALIGN", True)

torchaudio/csrc/ffmpeg/CMakeLists.txt

-message(STATUS "FFMPEG_ROOT=$ENV{FFMPEG_ROOT}")
-find_package(FFMPEG 4.1 REQUIRED COMPONENTS avdevice avfilter avformat avcodec avutil)
-add_library(ffmpeg INTERFACE)
-target_include_directories(ffmpeg INTERFACE "${FFMPEG_INCLUDE_DIRS}")
-target_link_libraries(ffmpeg INTERFACE "${FFMPEG_LIBRARIES}")
-
-
 set(
   sources
   ffmpeg.cpp