cmake build [skip ci]

CMakeLists.txt

+cmake_minimum_required(VERSION 3.0)
+project(torchcluster)
+set(CMAKE_CXX_STANDARD 14)
+set(TORCHCLUSTER_VERSION 1.5.4)
+
+option(WITH_CUDA "Enable CUDA support" OFF)
+
+if(WITH_CUDA)
+  enable_language(CUDA)
+  add_definitions(-D__CUDA_NO_HALF_OPERATORS__)
+endif()
+
+find_package(Python3 COMPONENTS Development)
+find_package(Torch REQUIRED)
+
+file(GLOB HEADERS csrc/cluster.h)
+file(GLOB OPERATOR_SOURCES csrc/cpu/*.h csrc/cpu/*.cpp csrc/*.cpp)
+if(WITH_CUDA)
+  file(GLOB OPERATOR_SOURCES ${OPERATOR_SOURCES} csrc/cuda/*.h csrc/cuda/*.cu)
+endif()
+
+add_library(${PROJECT_NAME} SHARED ${OPERATOR_SOURCES})
+target_link_libraries(${PROJECT_NAME} PRIVATE ${TORCH_LIBRARIES} Python3::Python)
+set_target_properties(${PROJECT_NAME} PROPERTIES EXPORT_NAME TorchCluster)
+
+target_include_directories(${PROJECT_NAME} INTERFACE
+  $<BUILD_INTERFACE:${HEADERS}>
+  $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
+
+include(GNUInstallDirs)
+include(CMakePackageConfigHelpers)
+
+set(TORCHCLUSTER_CMAKECONFIG_INSTALL_DIR "share/cmake/TorchCluster" CACHE STRING "install path for TorchClusterConfig.cmake")
+
+configure_package_config_file(cmake/TorchClusterConfig.cmake.in
+  "${CMAKE_CURRENT_BINARY_DIR}/TorchClusterConfig.cmake"
+  INSTALL_DESTINATION ${TORCHCLUSTER_CMAKECONFIG_INSTALL_DIR})
+
+write_basic_package_version_file(${CMAKE_CURRENT_BINARY_DIR}/TorchClusterConfigVersion.cmake
+  VERSION ${TORCHCLUSTER_VERSION}
+  COMPATIBILITY AnyNewerVersion)
+
+install(FILES ${CMAKE_CURRENT_BINARY_DIR}/TorchClusterConfig.cmake
+  ${CMAKE_CURRENT_BINARY_DIR}/TorchClusterConfigVersion.cmake
+  DESTINATION ${TORCHCLUSTER_CMAKECONFIG_INSTALL_DIR})
+
+install(TARGETS ${PROJECT_NAME}
+  EXPORT TorchClusterTargets
+  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+  )
+
+install(EXPORT TorchClusterTargets
+  NAMESPACE TorchCluster::
+  DESTINATION ${TORCHCLUSTER_CMAKECONFIG_INSTALL_DIR})
+
+install(FILES ${HEADERS} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${PROJECT_NAME})
+install(FILES
+  csrc/cpu/fps_cpu.h
+  csrc/cpu/graclus_cpu.h
+  csrc/cpu/grid_cpu.h
+  csrc/cpu/rw_cpu.h
+  csrc/cpu/sampler_cpu.h
+  DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${PROJECT_NAME}/cpu)
+if(WITH_CUDA)
+  install(FILES
+    csrc/cuda/fps_cuda.h
+    csrc/cuda/graclus_cuda.h
+    csrc/cuda/grid_cuda.h
+    csrc/cuda/knn_cuda.h
+    csrc/cuda/nearest_cuda.h
+    csrc/cuda/radius_cuda.h
+    csrc/cuda/rw_cuda.h
+    DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${PROJECT_NAME}/cuda)
+endif()

README.md

@@ -241,3 +241,16 @@ tensor([[0, 1, 2, 4],
 ```
 python setup.py test
 ```
+
+## C++ API
+
+`torch-cluster` also offers a C++ API that contains C++ equivalent of python models.
+
+```
+mkdir build
+cd build
+# Add -DWITH_CUDA=on support for the CUDA if needed
+cmake ..
+make
+make install
+```

cmake/TorchClusterConfig.cmake.in

+# TorchClusterConfig.cmake
+# --------------------
+#
+# Exported targets:: Cluster
+#
+
+@PACKAGE_INIT@
+
+set(PN TorchCluster)
+set(${PN}_INCLUDE_DIR "${PACKAGE_PREFIX_DIR}/@CMAKE_INSTALL_INCLUDEDIR@")
+set(${PN}_LIBRARY "")
+set(${PN}_DEFINITIONS USING_${PN})
+
+check_required_components(${PN})
+
+
+if(NOT (CMAKE_VERSION VERSION_LESS 3.0))
+#-----------------------------------------------------------------------------
+# Don't include targets if this file is being picked up by another
+# project which has already built this as a subproject
+#-----------------------------------------------------------------------------
+if(NOT TARGET ${PN}::TorchCluster)
+include("${CMAKE_CURRENT_LIST_DIR}/${PN}Targets.cmake")
+
+if(NOT TARGET torch_library)
+find_package(Torch REQUIRED)
+endif()
+if(NOT TARGET Python3::Python)
+find_package(Python3 COMPONENTS Development)
+endif()
+target_link_libraries(TorchCluster::TorchCluster INTERFACE ${TORCH_LIBRARIES} Python3::Python)
+
+if(@WITH_CUDA@)
+  target_compile_definitions(TorchCluster::TorchCluster INTERFACE WITH_CUDA)
+endif()
+
+endif()
+endif()

csrc/cluster.h

+#pragma once
+
+#include <torch/extension.h>
+
+int64_t cuda_version();
+
+torch::Tensor fps(torch::Tensor src, torch::Tensor ptr, double ratio,
+                  bool random_start);
+
+torch::Tensor graclus(torch::Tensor rowptr, torch::Tensor col,
+                      torch::optional<torch::Tensor> optional_weight);
+
+torch::Tensor grid(torch::Tensor pos, torch::Tensor size,
+                   torch::optional<torch::Tensor> optional_start,
+                   torch::optional<torch::Tensor> optional_end);
+
+torch::Tensor knn(torch::Tensor x, torch::Tensor y, torch::Tensor ptr_x,
+                  torch::Tensor ptr_y, int64_t k, bool cosine);
+
+torch::Tensor nearest(torch::Tensor x, torch::Tensor y, torch::Tensor ptr_x,
+                      torch::Tensor ptr_y);
+
+torch::Tensor radius(torch::Tensor x, torch::Tensor y, torch::Tensor ptr_x,
+                     torch::Tensor ptr_y, double r, int64_t max_num_neighbors);
+
+torch::Tensor random_walk(torch::Tensor rowptr, torch::Tensor col,
+                          torch::Tensor start, int64_t walk_length, double p,
+                          double q);
+
+torch::Tensor neighbor_sampler(torch::Tensor start, torch::Tensor rowptr,
+                               int64_t count, double factor);