2.3.2-dtk-22.10.1

cmake/external/glog.cmake

+# Copyright (c) 2016 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+include(ExternalProject)
+
+set(GLOG_PREFIX_DIR ${THIRD_PARTY_PATH}/glog)
+set(GLOG_INSTALL_DIR ${THIRD_PARTY_PATH}/install/glog)
+set(GLOG_INCLUDE_DIR
+    "${GLOG_INSTALL_DIR}/include"
+    CACHE PATH "glog include directory." FORCE)
+set(GLOG_REPOSITORY ${GIT_URL}/google/glog.git)
+set(GLOG_TAG v0.4.0)
+
+if(WIN32)
+  set(GLOG_LIBRARIES
+      "${GLOG_INSTALL_DIR}/lib/glog.lib"
+      CACHE FILEPATH "glog library." FORCE)
+  set(GLOG_CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4267 /wd4530")
+  add_definitions("/DGOOGLE_GLOG_DLL_DECL=")
+else()
+  set(GLOG_LIBRARIES
+      "${GLOG_INSTALL_DIR}/lib/libglog.a"
+      CACHE FILEPATH "glog library." FORCE)
+  set(GLOG_CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
+endif()
+
+include_directories(${GLOG_INCLUDE_DIR})
+
+if(WITH_ARM_BRPC)
+  set(ARM_GLOG_URL
+      "https://paddlerec.bj.bcebos.com/online_infer/arm_brpc_ubuntu18/arm_glog.tar.gz"
+      CACHE STRING "" FORCE)
+  set(GLOG_SOURCE_DIR ${THIRD_PARTY_PATH}/glog/src/extern_glog)
+  file(
+    WRITE ${GLOG_SOURCE_DIR}/CMakeLists.txt
+    "PROJECT(ARM_GLOGS)\n" "cmake_minimum_required(VERSION 3.0)\n"
+    "install(DIRECTORY arm_glog/include arm_glog/lib\n"
+    "        DESTINATION . USE_SOURCE_PERMISSIONS)\n")
+  ExternalProject_Add(
+    extern_glog
+    ${EXTERNAL_PROJECT_LOG_ARGS} ${SHALLOW_CLONE}
+    DEPENDS gflags
+    PREFIX ${GLOG_PREFIX_DIR}
+    DOWNLOAD_DIR ${GLOG_SOURCE_DIR}
+    DOWNLOAD_COMMAND rm -rf arm_glog.tar.gz && wget --no-check-certificate
+                     ${ARM_GLOG_URL} && tar zxvf arm_glog.tar.gz
+    #DOWNLOAD_COMMAND    cp /home/wangbin44/Paddle/build/arm_glog.tar.gz .
+    #                    && tar zxvf arm_glog.tar.gz
+    UPDATE_COMMAND ""
+    CMAKE_ARGS -DCMAKE_INSTALL_PREFIX:PATH=${GLOG_INSTALL_DIR}
+               -DCMAKE_BUILD_TYPE:STRING=${THIRD_PARTY_BUILD_TYPE}
+    CMAKE_CACHE_ARGS -DCMAKE_INSTALL_PREFIX:PATH=${GLOG_INSTALL_DIR}
+                     -DCMAKE_BUILD_TYPE:STRING=${THIRD_PARTY_BUILD_TYPE}
+    BUILD_BYPRODUCTS ${GLOG_LIBRARIES})
+else()
+  ExternalProject_Add(
+    extern_glog
+    ${EXTERNAL_PROJECT_LOG_ARGS} ${SHALLOW_CLONE}
+    GIT_REPOSITORY ${GLOG_REPOSITORY}
+    GIT_TAG ${GLOG_TAG}
+    DEPENDS gflags
+    PREFIX ${GLOG_PREFIX_DIR}
+    UPDATE_COMMAND ""
+    CMAKE_ARGS -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}
+               -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
+               -DCMAKE_CXX_FLAGS=${GLOG_CMAKE_CXX_FLAGS}
+               -DCMAKE_CXX_FLAGS_RELEASE=${CMAKE_CXX_FLAGS_RELEASE}
+               -DCMAKE_CXX_FLAGS_DEBUG=${CMAKE_CXX_FLAGS_DEBUG}
+               -DCMAKE_C_FLAGS=${CMAKE_C_FLAGS}
+               -DCMAKE_C_FLAGS_DEBUG=${CMAKE_C_FLAGS_DEBUG}
+               -DCMAKE_C_FLAGS_RELEASE=${CMAKE_C_FLAGS_RELEASE}
+               -DCMAKE_INSTALL_PREFIX=${GLOG_INSTALL_DIR}
+               -DCMAKE_INSTALL_LIBDIR=${GLOG_INSTALL_DIR}/lib
+               -DCMAKE_POSITION_INDEPENDENT_CODE=ON
+               -DWITH_GFLAGS=OFF
+               -DBUILD_TESTING=OFF
+               -DCMAKE_BUILD_TYPE=${THIRD_PARTY_BUILD_TYPE}
+               ${EXTERNAL_OPTIONAL_ARGS}
+    CMAKE_CACHE_ARGS
+      -DCMAKE_INSTALL_PREFIX:PATH=${GLOG_INSTALL_DIR}
+      -DCMAKE_INSTALL_LIBDIR:PATH=${GLOG_INSTALL_DIR}/lib
+      -DCMAKE_POSITION_INDEPENDENT_CODE:BOOL=ON
+      -DCMAKE_BUILD_TYPE:STRING=${THIRD_PARTY_BUILD_TYPE}
+    BUILD_BYPRODUCTS ${GLOG_LIBRARIES})
+endif()
+
+add_library(glog STATIC IMPORTED GLOBAL)
+set_property(TARGET glog PROPERTY IMPORTED_LOCATION ${GLOG_LIBRARIES})
+add_dependencies(glog extern_glog gflags)
+link_libraries(glog)

cmake/external/gloo.cmake

+# Copyright (c) 2019 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+include(ExternalProject)
+
+set(GLOO_PROJECT "extern_gloo")
+set(GLOO_PREFIX_DIR ${THIRD_PARTY_PATH}/gloo)
+set(GLOO_SOURCE_DIR ${THIRD_PARTY_PATH}/gloo/src/extern_gloo)
+set(GLOO_INSTALL_DIR ${THIRD_PARTY_PATH}/install/gloo)
+set(GLOO_INCLUDE_DIR
+    "${GLOO_INSTALL_DIR}/include"
+    CACHE PATH "gloo include directory." FORCE)
+set(GLOO_LIBRARY_DIR
+    "${GLOO_INSTALL_DIR}/lib"
+    CACHE PATH "gloo library directory." FORCE)
+# As we add extra features for gloo, we use the non-official repo
+set(GLOO_REPOSITORY ${GIT_URL}/ziyoujiyi/gloo.git)
+set(GLOO_TAG v0.0.3)
+set(GLOO_LIBRARIES
+    "${GLOO_INSTALL_DIR}/lib/libgloo.a"
+    CACHE FILEPATH "gloo library." FORCE)
+
+include_directories(${GLOO_INCLUDE_DIR})
+
+if(WITH_ASCEND OR WITH_ASCEND_CL)
+  ExternalProject_Add(
+    ${GLOO_PROJECT}
+    ${EXTERNAL_PROJECT_LOG_ARGS} ${SHALLOW_CLONE}
+    GIT_REPOSITORY ${GLOO_REPOSITORY}
+    GIT_TAG ${GLOO_TAG}
+    PREFIX "${GLOO_PREFIX_DIR}"
+    UPDATE_COMMAND ""
+    CONFIGURE_COMMAND ""
+    BUILD_COMMAND
+      mkdir -p ${GLOO_SOURCE_DIR}/build && cd ${GLOO_SOURCE_DIR}/build && cmake
+      .. -DCMAKE_CXX_FLAGS=${CMAKE_CXX_FLAGS} && make && mkdir -p
+      ${GLOO_LIBRARY_DIR} ${GLOO_INCLUDE_DIR}/gloo
+    INSTALL_COMMAND ${CMAKE_COMMAND} -E copy
+                    ${GLOO_SOURCE_DIR}/build/gloo/libgloo.a ${GLOO_LIBRARY_DIR}
+    COMMAND ${CMAKE_COMMAND} -E copy_directory "${GLOO_SOURCE_DIR}/gloo/"
+            "${GLOO_INCLUDE_DIR}/gloo"
+    BUILD_BYPRODUCTS ${GLOO_LIBRARIES})
+else()
+  ExternalProject_Add(
+    ${GLOO_PROJECT}
+    ${EXTERNAL_PROJECT_LOG_ARGS} ${SHALLOW_CLONE}
+    GIT_REPOSITORY ${GLOO_REPOSITORY}
+    GIT_TAG ${GLOO_TAG}
+    PREFIX "${GLOO_PREFIX_DIR}"
+    UPDATE_COMMAND ""
+    CONFIGURE_COMMAND ""
+    BUILD_COMMAND
+      mkdir -p ${GLOO_SOURCE_DIR}/build && cd ${GLOO_SOURCE_DIR}/build && cmake
+      .. -DCMAKE_CXX_FLAGS=${CMAKE_CXX_FLAGS} && make && mkdir -p
+      ${GLOO_LIBRARY_DIR} ${GLOO_INCLUDE_DIR}/gloo
+    INSTALL_COMMAND ${CMAKE_COMMAND} -E copy
+                    ${GLOO_SOURCE_DIR}/build/gloo/libgloo.a ${GLOO_LIBRARY_DIR}
+    COMMAND ${CMAKE_COMMAND} -E copy_directory "${GLOO_SOURCE_DIR}/gloo/"
+            "${GLOO_INCLUDE_DIR}/gloo"
+    BUILD_BYPRODUCTS ${GLOO_LIBRARIES})
+endif()
+
+add_library(gloo STATIC IMPORTED GLOBAL)
+set_property(TARGET gloo PROPERTY IMPORTED_LOCATION ${GLOO_LIBRARIES})
+add_dependencies(gloo ${GLOO_PROJECT})

cmake/external/gtest.cmake

+# Copyright (c) 2016 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+#FIXME:(gongwb) Move brpc's gtest dependency.
+
+if(WITH_TESTING)
+  enable_testing()
+endif()
+
+include(GNUInstallDirs)
+include(ExternalProject)
+
+set(GTEST_PREFIX_DIR ${THIRD_PARTY_PATH}/gtest)
+set(GTEST_INSTALL_DIR ${THIRD_PARTY_PATH}/install/gtest)
+set(GTEST_INCLUDE_DIR
+    "${GTEST_INSTALL_DIR}/include"
+    CACHE PATH "gtest include directory." FORCE)
+set(GTEST_REPOSITORY ${GIT_URL}/google/googletest.git)
+set(GTEST_TAG release-1.8.1)
+
+include_directories(${GTEST_INCLUDE_DIR})
+
+if(WIN32)
+  set(GTEST_LIBRARIES
+      "${GTEST_INSTALL_DIR}/${CMAKE_INSTALL_LIBDIR}/gtest.lib"
+      CACHE FILEPATH "gtest libraries." FORCE)
+  set(GTEST_MAIN_LIBRARIES
+      "${GTEST_INSTALL_DIR}/${CMAKE_INSTALL_LIBDIR}/gtest_main.lib"
+      CACHE FILEPATH "gtest main libraries." FORCE)
+  set(GMOCK_LIBRARIES
+      "${GTEST_INSTALL_DIR}/${CMAKE_INSTALL_LIBDIR}/libgmock.lib"
+      CACHE FILEPATH "gmock libraries." FORCE)
+  string(REPLACE "/w " "" GTEST_CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
+  string(REPLACE "/w " "" GTEST_CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
+  string(REPLACE "/W0 " "" GTEST_CMAKE_C_FLAGS "${GTEST_CMAKE_C_FLAGS}")
+  string(REPLACE "/W0 " "" GTEST_CMAKE_CXX_FLAGS "${GTEST_CMAKE_CXX_FLAGS}")
+else()
+  set(GTEST_LIBRARIES
+      "${GTEST_INSTALL_DIR}/${CMAKE_INSTALL_LIBDIR}/libgtest.a"
+      CACHE FILEPATH "gtest libraries." FORCE)
+  set(GTEST_MAIN_LIBRARIES
+      "${GTEST_INSTALL_DIR}/${CMAKE_INSTALL_LIBDIR}/libgtest_main.a"
+      CACHE FILEPATH "gtest main libraries." FORCE)
+  set(GMOCK_LIBRARIES
+      "${GTEST_INSTALL_DIR}/${CMAKE_INSTALL_LIBDIR}/libgmock.a"
+      CACHE FILEPATH "gmock libraries." FORCE)
+  set(GTEST_CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
+  set(GTEST_CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
+endif()
+
+if(WITH_MKLML)
+  # wait for mklml downloading completed
+  set(GTEST_DEPENDS ${MKLML_PROJECT})
+endif()
+
+ExternalProject_Add(
+  extern_gtest
+  ${EXTERNAL_PROJECT_LOG_ARGS} ${SHALLOW_CLONE}
+  GIT_REPOSITORY ${GTEST_REPOSITORY}
+  GIT_TAG ${GTEST_TAG}
+  DEPENDS ${GTEST_DEPENDS}
+  PREFIX ${GTEST_PREFIX_DIR}
+  UPDATE_COMMAND ""
+  CMAKE_ARGS -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}
+             -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
+             -DCMAKE_CXX_FLAGS=${GTEST_CMAKE_CXX_FLAGS}
+             -DCMAKE_CXX_FLAGS_RELEASE=${CMAKE_CXX_FLAGS_RELEASE}
+             -DCMAKE_CXX_FLAGS_DEBUG=${CMAKE_CXX_FLAGS_DEBUG}
+             -DCMAKE_C_FLAGS=${GTEST_CMAKE_C_FLAGS}
+             -DCMAKE_C_FLAGS_DEBUG=${CMAKE_C_FLAGS_DEBUG}
+             -DCMAKE_C_FLAGS_RELEASE=${CMAKE_C_FLAGS_RELEASE}
+             -DCMAKE_INSTALL_PREFIX=${GTEST_INSTALL_DIR}
+             -DCMAKE_POSITION_INDEPENDENT_CODE=ON
+             -DBUILD_GMOCK=ON
+             -Dgtest_disable_pthreads=ON
+             -Dgtest_force_shared_crt=ON
+             -DCMAKE_BUILD_TYPE=${THIRD_PARTY_BUILD_TYPE}
+             ${EXTERNAL_OPTIONAL_ARGS}
+  CMAKE_CACHE_ARGS
+    -DCMAKE_INSTALL_PREFIX:PATH=${GTEST_INSTALL_DIR}
+    -DCMAKE_POSITION_INDEPENDENT_CODE:BOOL=ON
+    -DCMAKE_BUILD_TYPE:STRING=${THIRD_PARTY_BUILD_TYPE}
+  BUILD_BYPRODUCTS ${GTEST_LIBRARIES}
+  BUILD_BYPRODUCTS ${GTEST_MAIN_LIBRARIES}
+  BUILD_BYPRODUCTS ${GMOCK_LIBRARIES})
+
+add_library(gtest STATIC IMPORTED GLOBAL)
+set_property(TARGET gtest PROPERTY IMPORTED_LOCATION ${GTEST_LIBRARIES})
+add_dependencies(gtest extern_gtest)
+
+add_library(gtest_main STATIC IMPORTED GLOBAL)
+set_property(TARGET gtest_main PROPERTY IMPORTED_LOCATION
+                                        ${GTEST_MAIN_LIBRARIES})
+add_dependencies(gtest_main extern_gtest)
+
+add_library(gmock STATIC IMPORTED GLOBAL)
+set_property(TARGET gmock PROPERTY IMPORTED_LOCATION ${GMOCK_LIBRARIES})
+add_dependencies(gmock extern_gtest)

cmake/external/lapack.cmake

+# Copyright (c) 2021 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+include(ExternalProject)
+
+set(LAPACK_PREFIX_DIR ${THIRD_PARTY_PATH}/lapack)
+set(LAPACK_SOURCE_DIR ${THIRD_PARTY_PATH}/lapack/src/extern_lapack)
+set(LAPACK_INSTALL_DIR ${THIRD_PARTY_PATH}/install/lapack)
+set(LAPACK_LIB_DIR ${LAPACK_INSTALL_DIR}/lib)
+
+# Note(zhouwei): lapack need fortan compiler which many machines don't have, so use precompiled library.
+# use lapack tag v3.10.0 on 06/28/2021 https://github.com/Reference-LAPACK/lapack
+if(LINUX)
+  set(LAPACK_VER
+      "lapack_lnx_v3.10.0.20210628"
+      CACHE STRING "" FORCE)
+  set(LAPACK_URL
+      "https://paddlepaddledeps.bj.bcebos.com/${LAPACK_VER}.tar.gz"
+      CACHE STRING "" FORCE)
+  set(LAPACK_URL_MD5 71f8cc8237a8571692f3e07f9a4f25f6)
+  set(GNU_RT_LIB_1 "${LAPACK_LIB_DIR}/libquadmath.so.0")
+  set(GFORTRAN_LIB "${LAPACK_LIB_DIR}/libgfortran.so.3")
+  set(BLAS_LIB "${LAPACK_LIB_DIR}/libblas.so.3")
+  set(LAPACK_LIB "${LAPACK_LIB_DIR}/liblapack.so.3")
+elseif(WIN32)
+  # Refer to [lapack-for-windows] http://icl.cs.utk.edu/lapack-for-windows/lapack/#lapacke
+  set(LAPACK_VER
+      "lapack_win_v3.10.0.20210628"
+      CACHE STRING "" FORCE)
+  set(LAPACK_URL
+      "https://paddlepaddledeps.bj.bcebos.com/${LAPACK_VER}.zip"
+      CACHE STRING "" FORCE)
+  set(LAPACK_URL_MD5 590d080392dcd5abbd5dca767a50b63a)
+  set(GNU_RT_LIB_1 "${LAPACK_LIB_DIR}/libquadmath-0.dll")
+  set(GNU_RT_LIB_2 "${LAPACK_LIB_DIR}/libgcc_s_seh-1.dll")
+  set(GFORTRAN_LIB "${LAPACK_LIB_DIR}/libgfortran-3.dll")
+  set(BLAS_LIB "${LAPACK_LIB_DIR}/libblas.dll")
+  set(LAPACK_LIB "${LAPACK_LIB_DIR}/liblapack.dll")
+else()
+  set(LAPACK_VER
+      "lapack_mac_v3.10.0.20210628"
+      CACHE STRING "" FORCE)
+  set(LAPACK_URL
+      "https://paddlepaddledeps.bj.bcebos.com/${LAPACK_VER}.tar.gz"
+      CACHE STRING "" FORCE)
+  set(LAPACK_URL_MD5 427aecf8dee8523de3566ca8e47944d7)
+  set(GNU_RT_LIB_1 "${LAPACK_LIB_DIR}/libquadmath.0.dylib")
+  set(GNU_RT_LIB_2 "${LAPACK_LIB_DIR}/libgcc_s.1.dylib")
+  set(GFORTRAN_LIB "${LAPACK_LIB_DIR}/libgfortran.5.dylib")
+  set(BLAS_LIB "${LAPACK_LIB_DIR}/libblas.3.dylib")
+  set(LAPACK_LIB "${LAPACK_LIB_DIR}/liblapack.3.dylib")
+endif()
+
+ExternalProject_Add(
+  extern_lapack
+  ${EXTERNAL_PROJECT_LOG_ARGS}
+  URL ${LAPACK_URL}
+  URL_MD5 ${LAPACK_URL_MD5}
+  PREFIX ${LAPACK_PREFIX_DIR}
+  DOWNLOAD_NO_PROGRESS 1
+  PATCH_COMMAND ""
+  UPDATE_COMMAND ""
+  CONFIGURE_COMMAND ""
+  BUILD_COMMAND ""
+  INSTALL_COMMAND ${CMAKE_COMMAND} -E copy_directory ${LAPACK_SOURCE_DIR}
+                  ${LAPACK_LIB_DIR}
+  BUILD_BYPRODUCTS ${BLAS_LIB}
+  BUILD_BYPRODUCTS ${LAPACK_LIB})

cmake/external/leveldb.cmake

+# Copyright (c) 2016 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+include(ExternalProject)
+
+set(LEVELDB_PREFIX_DIR ${THIRD_PARTY_PATH}/leveldb)
+set(LEVELDB_INSTALL_DIR ${THIRD_PARTY_PATH}/install/leveldb)
+set(LEVELDB_INCLUDE_DIR
+    "${LEVELDB_INSTALL_DIR}/include"
+    CACHE PATH "leveldb include directory." FORCE)
+set(LEVELDB_LIBRARIES
+    "${LEVELDB_INSTALL_DIR}/lib/libleveldb.a"
+    CACHE FILEPATH "leveldb library." FORCE)
+include_directories(${LEVELDB_INCLUDE_DIR})
+
+ExternalProject_Add(
+  extern_leveldb
+  ${EXTERNAL_PROJECT_LOG_ARGS}
+  PREFIX ${LEVELDB_PREFIX_DIR}
+  GIT_REPOSITORY "https://github.com/google/leveldb"
+  GIT_TAG v1.18
+  UPDATE_COMMAND ""
+  CONFIGURE_COMMAND ""
+  BUILD_COMMAND CXXFLAGS=-fPIC make -j ${NUM_OF_PROCESSOR} libleveldb.a
+  INSTALL_COMMAND
+    mkdir -p ${LEVELDB_INSTALL_DIR}/lib/ && cp
+    ${LEVELDB_PREFIX_DIR}/src/extern_leveldb/libleveldb.a ${LEVELDB_LIBRARIES}
+    && cp -r ${LEVELDB_PREFIX_DIR}/src/extern_leveldb/include
+    ${LEVELDB_INSTALL_DIR}/
+  BUILD_IN_SOURCE 1
+  BUILD_BYPRODUCTS ${LEVELDB_LIBRARIES})
+
+add_dependencies(extern_leveldb snappy)
+
+add_library(leveldb STATIC IMPORTED GLOBAL)
+set_property(TARGET leveldb PROPERTY IMPORTED_LOCATION ${LEVELDB_LIBRARIES})
+add_dependencies(leveldb extern_leveldb)
+
+list(APPEND external_project_dependencies leveldb)

cmake/external/libmct.cmake

+# Copyright (c) 2017 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+include(ExternalProject)
+
+set(LIBMCT_PROJECT "extern_libmct")
+if((NOT DEFINED LIBMCT_VER) OR (NOT DEFINED LIBMCT_URL))
+  message(STATUS "use pre defined download url")
+  set(LIBMCT_VER
+      "0.1.0"
+      CACHE STRING "" FORCE)
+  set(LIBMCT_NAME
+      "libmct"
+      CACHE STRING "" FORCE)
+  set(LIBMCT_URL
+      "https://pslib.bj.bcebos.com/libmct/libmct.tar.gz"
+      CACHE STRING "" FORCE)
+endif()
+message(STATUS "LIBMCT_NAME: ${LIBMCT_NAME}, LIBMCT_URL: ${LIBMCT_URL}")
+set(LIBMCT_PREFIX_DIR "${THIRD_PARTY_PATH}/libmct")
+set(LIBMCT_DOWNLOAD_DIR "${LIBMCT_PREFIX_DIR}/src/${LIBMCT_PROJECT}")
+set(LIBMCT_DST_DIR "libmct")
+set(LIBMCT_INSTALL_ROOT "${THIRD_PARTY_PATH}/install")
+set(LIBMCT_INSTALL_DIR ${LIBMCT_INSTALL_ROOT}/${LIBMCT_DST_DIR})
+set(LIBMCT_ROOT ${LIBMCT_INSTALL_DIR})
+set(LIBMCT_INC_DIR ${LIBMCT_ROOT}/include)
+set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_RPATH}" "${LIBMCT_ROOT}/lib")
+
+include_directories(${LIBMCT_INC_DIR})
+
+file(
+  WRITE ${LIBMCT_DOWNLOAD_DIR}/CMakeLists.txt
+  "PROJECT(LIBMCT)\n" "cmake_minimum_required(VERSION 3.0)\n"
+  "install(DIRECTORY ${LIBMCT_NAME}/include ${LIBMCT_NAME}/lib \n"
+  "        DESTINATION ${LIBMCT_DST_DIR})\n")
+
+ExternalProject_Add(
+  ${LIBMCT_PROJECT}
+  ${EXTERNAL_PROJECT_LOG_ARGS}
+  PREFIX ${LIBMCT_PREFIX_DIR}
+  DOWNLOAD_DIR ${LIBMCT_DOWNLOAD_DIR}
+  DOWNLOAD_COMMAND
+    wget --no-check-certificate ${LIBMCT_URL} -c -q -O ${LIBMCT_NAME}.tar.gz &&
+    tar --no-same-owner -zxvf ${LIBMCT_NAME}.tar.gz
+  DOWNLOAD_NO_PROGRESS 1
+  UPDATE_COMMAND ""
+  CMAKE_ARGS -DCMAKE_INSTALL_PREFIX=${LIBMCT_INSTALL_ROOT}
+             -DCMAKE_BUILD_TYPE=${THIRD_PARTY_BUILD_TYPE}
+  CMAKE_CACHE_ARGS -DCMAKE_INSTALL_PREFIX:PATH=${LIBMCT_INSTALL_ROOT}
+                   -DCMAKE_BUILD_TYPE=${THIRD_PARTY_BUILD_TYPE})
+
+add_library(libmct INTERFACE)
+
+add_dependencies(libmct ${LIBMCT_PROJECT})

cmake/external/libxsmm.cmake

+# Copyright (c) 2018 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+include(ExternalProject)
+
+set(LIBXSMM_PREFIX_DIR ${THIRD_PARTY_PATH}/libxsmm)
+set(LIBXSMM_INSTALL_DIR ${THIRD_PARTY_PATH}/install/libxsmm)
+set(LIBXSMM_INCLUDE_DIR
+    "${LIBXSMM_INSTALL_DIR}/include"
+    CACHE PATH "LIBXSMM include directory." FORCE)
+set(LIBXSMM_LIBRARY_DIR
+    "${LIBXSMM_INSTALL_DIR}/lib"
+    CACHE PATH "LIBXSMM library directory." FORCE)
+set(LIBXSMM_LIB "${LIBXSMM_LIBRARY_DIR}/libxsmm.a")
+set(LIBXSMMNOBLAS_LIB "${LIBXSMM_LIBRARY_DIR}/libxsmmnoblas.a")
+
+ExternalProject_Add(
+  extern_libxsmm
+  ${SHALLOW_CLONE}
+  GIT_REPOSITORY "${GIT_URL}/hfp/libxsmm.git"
+  GIT_TAG "7cc03b5b342fdbc6b6d990b190671c5dbb8489a2"
+  PREFIX ${LIBXSMM_PREFIX_DIR}
+  UPDATE_COMMAND ""
+  CONFIGURE_COMMAND ""
+  BUILD_IN_SOURCE 1
+  BUILD_COMMAND $(MAKE) --silent PREFIX=${LIBXSMM_INSTALL_DIR} CXX=g++ CC=gcc
+                WARP=0 install
+  INSTALL_COMMAND ""
+  BUILD_BYPRODUCTS ${LIBXSMM_LIB}
+  BUILD_BYPRODUCTS ${LIBXSMMNOBLAS_LIB})
+add_library(libxsmm STATIC IMPORTED GLOBAL)
+set_property(TARGET libxsmm PROPERTY IMPORTED_LOCATION "${LIBXSMM_LIB}")
+set_property(TARGET libxsmm PROPERTY IMPORTED_LOCATION "${LIBXSMMNOBLAS_LIB}")
+
+message(STATUS "Libxsmm library: ${LIBXSMM_LIBS}")
+include_directories(${LIBXSMM_INCLUDE_DIR})
+add_definitions(-DPADDLE_WITH_LIBXSMM)
+add_dependencies(libxsmm extern_libxsmm)

cmake/external/lite.cmake

+# Copyright (c) 2019 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+if(NOT LINUX)
+  message("Paddle-lite will not build because the required Linux do not exist.")
+  set(WITH_LITE OFF)
+  return()
+endif()
+
+if(LITE_WITH_XPU)
+  add_definitions(-DLITE_SUBGRAPH_WITH_XPU)
+  if(WITH_AARCH64)
+    set(XPU_SDK_ENV "kylin_aarch64")
+  elseif(WITH_SUNWAY)
+    set(XPU_SDK_ENV "deepin_sw6_64")
+  elseif(WITH_BDCENTOS)
+    set(XPU_SDK_ENV "bdcentos_x86_64")
+  elseif(WITH_UBUNTU)
+    set(XPU_SDK_ENV "ubuntu_x86_64")
+  elseif(WITH_CENTOS)
+    set(XPU_SDK_ENV "centos7_x86_64")
+  else()
+    set(XPU_SDK_ENV "ubuntu_x86_64")
+  endif()
+endif()
+
+if(LITE_WITH_NNADAPTER)
+  add_definitions(-DLITE_SUBGRAPH_WITH_NNADAPTER)
+  if(NNADAPTER_WITH_HUAWEI_ASCEND_NPU)
+    add_definitions(-DLITE_SUBGRAPH_WITH_NPU)
+    set(NPU_SDK_ROOT
+        "/usr/local/Ascend/ascend-toolkit/latest"
+        CACHE STRING "default NPU SDK ROOT")
+  endif()
+endif()
+
+if(NOT LITE_SOURCE_DIR OR NOT LITE_BINARY_DIR)
+  include(ExternalProject)
+  set(LITE_PROJECT extern_lite)
+  set(LITE_PREFIX_DIR ${THIRD_PARTY_PATH}/lite)
+  set(LITE_INSTALL_DIR ${THIRD_PARTY_PATH}/install/lite)
+
+  if(NOT LITE_GIT_TAG)
+    set(LITE_GIT_TAG 81ef66554099800c143a0feff6e0a491b3b0d12e)
+  endif()
+
+  if(NOT CUDA_ARCH_NAME)
+    set(CUDA_ARCH_NAME "Auto")
+  endif()
+
+  # No quotes, so cmake can resolve it as a command with arguments.
+  if(WITH_ARM)
+    set(LITE_BUILD_COMMAND $(MAKE) publish_inference -j)
+    message(WARNING "BUILD_COMMAND: ${LITE_BUILD_COMMAND}")
+    set(LITE_OPTIONAL_ARGS
+        -DWITH_MKL=OFF
+        -DLITE_WITH_CUDA=OFF
+        -DWITH_MKLDNN=OFF
+        -DLITE_WITH_X86=OFF
+        -DLITE_WITH_LIGHT_WEIGHT_FRAMEWORK=ON
+        -DLITE_WITH_PROFILE=OFF
+        -DARM_TARGET_OS=armlinux
+        -DWITH_LITE=ON
+        -DWITH_PYTHON=OFF
+        -DWITH_TESTING=OFF
+        -DLITE_BUILD_EXTRA=ON
+        -DLITE_WITH_XPU=${LITE_WITH_XPU}
+        -DXPU_SDK_URL=${XPU_BASE_URL}
+        -DXPU_SDK_ENV=${XPU_SDK_ENV}
+        -DLITE_WITH_NNADAPTER=${LITE_WITH_NNADAPTER}
+        -DNNADAPTER_WITH_HUAWEI_ASCEND_NPU=${NNADAPTER_WITH_HUAWEI_ASCEND_NPU}
+        -DNNADAPTER_HUAWEI_ASCEND_NPU_SDK_ROOT=${NPU_SDK_ROOT}
+        -DLITE_WITH_CODE_META_INFO=OFF
+        -DLITE_WITH_ARM=ON)
+    ExternalProject_Add(
+      ${LITE_PROJECT}
+      ${EXTERNAL_PROJECT_LOG_ARGS}
+      GIT_REPOSITORY "${GIT_URL}/PaddlePaddle/Paddle-Lite.git"
+      GIT_TAG ${LITE_GIT_TAG}
+      PREFIX ${LITE_PREFIX_DIR}
+      PATCH_COMMAND
+        mkdir -p ${LITE_PREFIX_DIR}/src/extern_lite-build/lite/gen_code && touch
+        ${LITE_PREFIX_DIR}/src/extern_lite-build/lite/gen_code/__generated_code__.cc
+        && sed -i "/aarch64-linux-gnu-gcc/d"
+        ${LITE_PREFIX_DIR}/src/extern_lite/cmake/os/armlinux.cmake && sed -i
+        "/aarch64-linux-gnu-g++/d"
+        ${LITE_PREFIX_DIR}/src/extern_lite/cmake/os/armlinux.cmake
+      UPDATE_COMMAND ""
+      BUILD_COMMAND ${LITE_BUILD_COMMAND}
+      INSTALL_COMMAND ""
+      CMAKE_ARGS -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}
+                 -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
+                 -DCMAKE_CXX_FLAGS=${LITE_CMAKE_CXX_FLAGS}
+                 -DCMAKE_CXX_FLAGS_RELEASE=${CMAKE_CXX_FLAGS_RELEASE}
+                 -DCMAKE_CXX_FLAGS_DEBUG=${CMAKE_CXX_FLAGS_DEBUG}
+                 -DCMAKE_C_FLAGS=${CMAKE_C_FLAGS}
+                 -DCMAKE_C_FLAGS_DEBUG=${CMAKE_C_FLAGS_DEBUG}
+                 -DCMAKE_C_FLAGS_RELEASE=${CMAKE_C_FLAGS_RELEASE}
+                 -DCMAKE_POSITION_INDEPENDENT_CODE=ON
+                 -DCMAKE_BUILD_TYPE=${THIRD_PARTY_BUILD_TYPE}
+                 ${EXTERNAL_OPTIONAL_ARGS}
+                 ${LITE_OPTIONAL_ARGS})
+  else()
+    set(LITE_BUILD_COMMAND $(MAKE) publish_inference -j)
+    set(LITE_OPTIONAL_ARGS
+        -DWITH_MKL=ON
+        -DLITE_WITH_CUDA=OFF
+        -DWITH_MKLDNN=OFF
+        -DLITE_WITH_X86=ON
+        -DLITE_WITH_PROFILE=OFF
+        -DWITH_LITE=OFF
+        -DLITE_WITH_LIGHT_WEIGHT_FRAMEWORK=OFF
+        -DWITH_PYTHON=OFF
+        -DWITH_TESTING=OFF
+        -DLITE_BUILD_EXTRA=ON
+        -DLITE_WITH_XPU=${LITE_WITH_XPU}
+        -DXPU_SDK_URL=${XPU_BASE_URL}
+        -DXPU_SDK_ENV=${XPU_SDK_ENV}
+        -DLITE_WITH_NNADAPTER=${LITE_WITH_NNADAPTER}
+        -DNNADAPTER_WITH_HUAWEI_ASCEND_NPU=${NNADAPTER_WITH_HUAWEI_ASCEND_NPU}
+        -DNNADAPTER_HUAWEI_ASCEND_NPU_SDK_ROOT=${NPU_SDK_ROOT}
+        -DLITE_WITH_CODE_META_INFO=OFF
+        -DLITE_WITH_ARM=OFF)
+
+    ExternalProject_Add(
+      ${LITE_PROJECT}
+      ${EXTERNAL_PROJECT_LOG_ARGS}
+      GIT_REPOSITORY "${GIT_URL}/PaddlePaddle/Paddle-Lite.git"
+      GIT_TAG ${LITE_GIT_TAG}
+      PREFIX ${LITE_PREFIX_DIR}
+      UPDATE_COMMAND ""
+      PATCH_COMMAND
+        sed -i
+        "s?NNadapter_bridges_path = os.path.abspath('..')+\"\/lite\/kernels\/nnadapter\/bridges\/paddle_use_bridges.h\"?NNadapter_bridges_path = os.path.abspath(\'..\')+\"\/extern_lite\/lite\/kernels\/nnadapter\/bridges\/paddle_use_bridges.h\"?"
+        ${LITE_PREFIX_DIR}/src/extern_lite//lite/tools/cmake_tools/record_supported_kernel_op.py
+      BUILD_COMMAND ${LITE_BUILD_COMMAND}
+      INSTALL_COMMAND ""
+      CMAKE_ARGS -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}
+                 -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
+                 -DCMAKE_CXX_FLAGS=${LITE_CMAKE_CXX_FLAGS}
+                 -DCMAKE_CXX_FLAGS_RELEASE=${CMAKE_CXX_FLAGS_RELEASE}
+                 -DCMAKE_CXX_FLAGS_DEBUG=${CMAKE_CXX_FLAGS_DEBUG}
+                 -DCMAKE_C_FLAGS=${CMAKE_C_FLAGS}
+                 -DCMAKE_C_FLAGS_DEBUG=${CMAKE_C_FLAGS_DEBUG}
+                 -DCMAKE_C_FLAGS_RELEASE=${CMAKE_C_FLAGS_RELEASE}
+                 -DCMAKE_POSITION_INDEPENDENT_CODE=ON
+                 -DCMAKE_BUILD_TYPE=${THIRD_PARTY_BUILD_TYPE}
+                 ${EXTERNAL_OPTIONAL_ARGS}
+                 ${LITE_OPTIONAL_ARGS})
+  endif()
+  ExternalProject_Get_Property(${LITE_PROJECT} BINARY_DIR)
+  ExternalProject_Get_Property(${LITE_PROJECT} SOURCE_DIR)
+  set(LITE_BINARY_DIR ${BINARY_DIR})
+  set(LITE_SOURCE_DIR ${SOURCE_DIR})
+
+endif()
+
+if(WITH_ARM)
+  if(LITE_WITH_XPU)
+    set(LITE_OUTPUT_BIN_DIR inference_lite_lib.armlinux.armv8.xpu)
+  elseif(LITE_WITH_NNADAPTER)
+    message("Enable LITE_WITH_NNADAPTER")
+    if(NNADAPTER_WITH_HUAWEI_ASCEND_NPU)
+      set(LITE_OUTPUT_BIN_DIR inference_lite_lib.armlinux.armv8.nnadapter)
+    endif()
+  else()
+    set(LITE_OUTPUT_BIN_DIR inference_lite_lib.armlinux.armv8)
+  endif()
+else()
+  set(LITE_OUTPUT_BIN_DIR inference_lite_lib)
+endif()
+
+message(STATUS "Paddle-lite BINARY_DIR: ${LITE_BINARY_DIR}")
+message(STATUS "Paddle-lite SOURCE_DIR: ${LITE_SOURCE_DIR}")
+include_directories(${LITE_SOURCE_DIR})
+include_directories(${LITE_BINARY_DIR})
+if(LITE_WITH_XPU)
+  include_directories(${LITE_BINARY_DIR}/third_party/install/xpu/xdnn/include/)
+  include_directories(${LITE_BINARY_DIR}/third_party/install/xpu/xre/include/)
+endif()
+
+function(external_lite_libs alias path)
+  add_library(${alias} SHARED IMPORTED GLOBAL)
+  set_property(TARGET ${alias} PROPERTY IMPORTED_LOCATION ${path})
+  if(LITE_PROJECT)
+    add_dependencies(${alias} ${LITE_PROJECT})
+  endif()
+endfunction()
+
+external_lite_libs(
+  lite_full_static
+  ${LITE_BINARY_DIR}/${LITE_OUTPUT_BIN_DIR}/cxx/lib/libpaddle_full_api_shared.so
+)
+set(LITE_SHARED_LIB
+    ${LITE_BINARY_DIR}/${LITE_OUTPUT_BIN_DIR}/cxx/lib/libpaddle_full_api_shared.so
+)
+
+if(LITE_WITH_NNADAPTER)
+  set(LITE_NNADAPTER_LIB
+      ${LITE_BINARY_DIR}/${LITE_OUTPUT_BIN_DIR}/cxx/lib/libnnadapter.so)
+  if(NNADAPTER_WITH_HUAWEI_ASCEND_NPU)
+    external_lite_libs(
+      lite_nnadapter
+      ${LITE_BINARY_DIR}/${LITE_OUTPUT_BIN_DIR}/cxx/lib/libnnadapter.so
+      ${LITE_BINARY_DIR}/${LITE_OUTPUT_BIN_DIR}/cxx/lib/libhuawei_ascend_npu.so)
+    set(LITE_DEPS lite_full_static lite_nnadapter)
+    set(LITE_NNADAPTER_NPU_LIB
+        ${LITE_BINARY_DIR}/${LITE_OUTPUT_BIN_DIR}/cxx/lib/libhuawei_ascend_npu.so
+    )
+  endif()
+else()
+  set(LITE_DEPS lite_full_static)
+endif()
+
+add_definitions(-DPADDLE_WITH_LITE)
+add_definitions(-DLITE_WITH_LOG)

cmake/external/llvm.cmake

+include(FetchContent)
+
+set(LLVM_DOWNLOAD_URL
+    https://paddle-inference-dist.bj.bcebos.com/infrt/llvm_b5149f4e66a49a98b67e8e2de4e24a4af8e2781b.tar.gz
+)
+set(LLVM_MD5 022819bb5760817013cf4b8a37e97d5e)
+
+set(FETCHCONTENT_BASE_DIR ${THIRD_PARTY_PATH}/llvm)
+set(FETCHCONTENT_QUIET OFF)
+FetchContent_Declare(
+  external_llvm
+  URL ${LLVM_DOWNLOAD_URL}
+  URL_MD5 ${LLVM_MD5}
+  PREFIX ${THIRD_PARTY_PATH}/llvm SOURCE_DIR ${THIRD_PARTY_PATH}/install/llvm)
+if(NOT LLVM_PATH)
+  FetchContent_GetProperties(external_llvm)
+  if(NOT external_llvm_POPULATED)
+    FetchContent_Populate(external_llvm)
+  endif()
+  set(LLVM_PATH ${THIRD_PARTY_PATH}/install/llvm)
+  set(LLVM_DIR ${THIRD_PARTY_PATH}/install/llvm/lib/cmake/llvm)
+  set(MLIR_DIR ${THIRD_PARTY_PATH}/install/llvm/lib/cmake/mlir)
+else()
+  set(LLVM_DIR ${LLVM_PATH}/lib/cmake/llvm)
+  set(MLIR_DIR ${LLVM_PATH}/lib/cmake/mlir)
+endif()
+
+if(${CMAKE_CXX_COMPILER} STREQUAL "clang++")
+  set(CMAKE_EXE_LINKER_FLAGS
+      "${CMAKE_EXE_LINKER_FLAGS} -stdlib=libc++ -lc++abi")
+endif()
+
+message(STATUS "set LLVM_DIR: ${LLVM_DIR}")
+message(STATUS "set MLIR_DIR: ${MLIR_DIR}")
+find_package(LLVM REQUIRED CONFIG HINTS ${LLVM_DIR})
+find_package(MLIR REQUIRED CONFIG HINTS ${MLIR_DIR})
+find_package(ZLIB REQUIRED)
+
+list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_DIR}")
+include(AddLLVM)
+
+include_directories(${LLVM_INCLUDE_DIRS})
+list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_DIR}")
+list(APPEND CMAKE_MODULE_PATH "${MLIR_CMAKE_DIR}")
+include(AddLLVM)
+include(TableGen)
+include(AddMLIR)
+
+message(STATUS "Found MLIR: ${MLIR_DIR}")
+message(STATUS "Found LLVM ${LLVM_PACKAGE_VERSION}")
+message(STATUS "Using LLVMConfig.cmake in: ${LLVM_DIR}")
+
+# To build with MLIR, the LLVM is build from source code using the following flags:
+
+#[==[
+cmake ../llvm  -G "Unix Makefiles" \
+  -DLLVM_ENABLE_PROJECTS="mlir;clang" \
+  -DLLVM_BUILD_EXAMPLES=OFF \
+  -DLLVM_TARGETS_TO_BUILD="X86" \
+  -DCMAKE_BUILD_TYPE=Release \
+  -DLLVM_ENABLE_ASSERTIONS=ON \
+  -DLLVM_ENABLE_ZLIB=OFF \
+  -DLLVM_ENABLE_RTTI=ON \
+  -DLLVM_INSTALL_UTILS=ON \
+  -DCMAKE_INSTALL_PREFIX=./install
+#]==]
+# The matched llvm-project version is b5149f4e66a49a98b67e8e2de4e24a4af8e2781b (currently a temporary commit)
+
+add_definitions(${LLVM_DEFINITIONS})
+
+llvm_map_components_to_libnames(
+  llvm_libs
+  Support
+  Core
+  irreader
+  X86
+  executionengine
+  orcjit
+  mcjit
+  all
+  codegen)
+
+message(STATUS "LLVM libs: ${llvm_libs}")
+
+get_property(mlir_libs GLOBAL PROPERTY MLIR_ALL_LIBS)
+message(STATUS "MLIR libs: ${mlir_libs}")
+add_definitions(${LLVM_DEFINITIONS})
+
+# The minimum needed libraries for MLIR IR parse and transform.
+set(MLIR_IR_LIBS MLIRAnalysis MLIRPass MLIRParser MLIRDialect MLIRIR MLIROptLib)
+
+# tb_base is the name of a xxx.td file (without the .td suffix)
+function(mlir_tablegen_on td_base)
+  set(options)
+  set(oneValueArgs DIALECT)
+  cmake_parse_arguments(mlir_tablegen_on "${options}" "${oneValueArgs}"
+                        "${multiValueArgs}" ${ARGN})
+
+  set(LLVM_TARGET_DEFINITIONS ${td_base}.td)
+  mlir_tablegen(${td_base}.hpp.inc -gen-op-decls)
+  mlir_tablegen(${td_base}.cpp.inc -gen-op-defs)
+  if(mlir_tablegen_on_DIALECT)
+    mlir_tablegen(${td_base}_dialect.hpp.inc --gen-dialect-decls
+                  -dialect=${mlir_tablegen_on_DIALECT})
+    mlir_tablegen(${td_base}_dialect.cpp.inc --gen-dialect-defs
+                  -dialect=${mlir_tablegen_on_DIALECT})
+  endif()
+  add_public_tablegen_target(${td_base}_IncGen)
+  add_custom_target(${td_base}_inc DEPENDS ${td_base}_IncGen)
+endfunction()
+
+function(mlir_add_rewriter td_base)
+  set(LLVM_TARGET_DEFINITIONS ${td_base}.td)
+  set(LLVM_TARGET_DEPENDS
+      ${LLVM_TARGET_DEPENDS}
+      ${CMAKE_SOURCE_DIR}/paddle/infrt/dialect/infrt/ir/infrt_base.td)
+  mlir_tablegen(${td_base}.cpp.inc -gen-rewriters)
+  add_public_tablegen_target(MLIR${td_base}IncGen)
+  add_dependencies(mlir-headers MLIR${td_base}IncGen)
+endfunction()
+
+# Execute the mlir script with infrt-exec program.
+# @name: name of the test
+# @script: path to the mlir script file
+function(infrt_exec_check name script)
+  add_test(
+    NAME ${name}
+    COMMAND
+      sh -c
+      "${CMAKE_BINARY_DIR}/paddle/infrt/host_context/infrt-exec -i ${CMAKE_CURRENT_SOURCE_DIR}/${script}| ${LLVM_PATH}/bin/FileCheck  ${CMAKE_CURRENT_SOURCE_DIR}/${script}"
+  )
+endfunction()

cmake/external/mkldnn.cmake

+# Copyright (c) 2017 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+include(ExternalProject)
+
+set(MKLDNN_PROJECT "extern_mkldnn")
+set(MKLDNN_PREFIX_DIR ${THIRD_PARTY_PATH}/mkldnn)
+set(MKLDNN_INSTALL_DIR ${THIRD_PARTY_PATH}/install/mkldnn)
+set(MKLDNN_INC_DIR
+    "${MKLDNN_INSTALL_DIR}/include"
+    CACHE PATH "mkldnn include directory." FORCE)
+set(MKLDNN_REPOSITORY ${GIT_URL}/oneapi-src/oneDNN.git)
+set(MKLDNN_TAG 9b186765dded79066e0cd9c17eb70b680b76fb8e)
+
+# Introduce variables:
+# * CMAKE_INSTALL_LIBDIR
+include(GNUInstallDirs)
+set(LIBDIR "lib")
+if(CMAKE_INSTALL_LIBDIR MATCHES ".*lib64$")
+  set(LIBDIR "lib64")
+endif()
+
+message(STATUS "Set ${MKLDNN_INSTALL_DIR}/${LIBDIR} to runtime path")
+set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
+set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_RPATH}"
+                        "${MKLDNN_INSTALL_DIR}/${LIBDIR}")
+
+include_directories(${MKLDNN_INC_DIR}
+)# For MKLDNN code to include internal headers.
+
+if(NOT WIN32)
+  set(MKLDNN_FLAG
+      "-Wno-error=strict-overflow -Wno-error=unused-result -Wno-error=array-bounds"
+  )
+  set(MKLDNN_FLAG "${MKLDNN_FLAG} -Wno-unused-result -Wno-unused-value")
+  set(MKLDNN_CFLAG "${CMAKE_C_FLAGS} ${MKLDNN_FLAG}")
+  set(MKLDNN_CXXFLAG "${CMAKE_CXX_FLAGS} ${MKLDNN_FLAG}")
+  set(MKLDNN_CXXFLAG_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
+  set(MKLDNN_CFLAG_RELEASE "${CMAKE_C_FLAGS_RELEASE}")
+  set(MKLDNN_LIB
+      "${MKLDNN_INSTALL_DIR}/${LIBDIR}/libdnnl.so"
+      CACHE FILEPATH "mkldnn library." FORCE)
+else()
+  set(MKLDNN_CXXFLAG "${CMAKE_CXX_FLAGS} /EHsc")
+  set(MKLDNN_CFLAG "${CMAKE_C_FLAGS}")
+  string(REPLACE "/O2 " "" MKLDNN_CFLAG_RELEASE "${CMAKE_C_FLAGS_RELEASE}")
+  string(REPLACE "/O2 " "" MKLDNN_CXXFLAG_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
+  set(MKLDNN_LIB
+      "${MKLDNN_INSTALL_DIR}/bin/mkldnn.lib"
+      CACHE FILEPATH "mkldnn library." FORCE)
+endif()
+
+if(LINUX)
+  set(BUILD_BYPRODUCTS_ARGS ${MKLDNN_LIB})
+else()
+  set(BUILD_BYPRODUCTS_ARGS "")
+endif()
+
+ExternalProject_Add(
+  ${MKLDNN_PROJECT}
+  ${EXTERNAL_PROJECT_LOG_ARGS} ${SHALLOW_CLONE}
+  GIT_REPOSITORY ${MKLDNN_REPOSITORY}
+  GIT_TAG ${MKLDNN_TAG}
+  DEPENDS ${MKLDNN_DEPENDS}
+  PREFIX ${MKLDNN_PREFIX_DIR}
+  UPDATE_COMMAND ""
+  #BUILD_ALWAYS        1
+  CMAKE_ARGS -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}
+             -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
+             -DCMAKE_CXX_FLAGS=${MKLDNN_CXXFLAG}
+             -DCMAKE_CXX_FLAGS_RELEASE=${MKLDNN_CXXFLAG_RELEASE}
+             -DCMAKE_CXX_FLAGS_DEBUG=${CMAKE_CXX_FLAGS_DEBUG}
+             -DCMAKE_C_FLAGS=${MKLDNN_CFLAG}
+             -DCMAKE_C_FLAGS_DEBUG=${CMAKE_C_FLAGS_DEBUG}
+             -DCMAKE_C_FLAGS_RELEASE=${MKLDNN_CFLAG_RELEASE}
+             -DCMAKE_INSTALL_PREFIX=${MKLDNN_INSTALL_DIR}
+             -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
+             -DCMAKE_POSITION_INDEPENDENT_CODE=ON
+             -DDNNL_BUILD_TESTS=OFF
+             -DDNNL_BUILD_EXAMPLES=OFF
+  CMAKE_CACHE_ARGS -DCMAKE_INSTALL_PREFIX:PATH=${MKLDNN_INSTALL_DIR}
+  BUILD_BYPRODUCTS ${BUILD_BYPRODUCTS_ARGS})
+
+message(STATUS "MKLDNN library: ${MKLDNN_LIB}")
+add_definitions(-DPADDLE_WITH_MKLDNN)
+# copy the real so.0 lib to install dir
+# it can be directly contained in wheel or capi
+if(WIN32)
+  set(MKLDNN_SHARED_LIB ${MKLDNN_INSTALL_DIR}/bin/mkldnn.dll)
+
+  file(TO_NATIVE_PATH ${MKLDNN_INSTALL_DIR} NATIVE_MKLDNN_INSTALL_DIR)
+  file(TO_NATIVE_PATH ${MKLDNN_SHARED_LIB} NATIVE_MKLDNN_SHARED_LIB)
+
+  add_custom_command(
+    OUTPUT ${MKLDNN_LIB}
+    COMMAND (copy ${NATIVE_MKLDNN_INSTALL_DIR}\\bin\\dnnl.dll
+             ${NATIVE_MKLDNN_SHARED_LIB} /Y)
+    COMMAND dumpbin /exports ${MKLDNN_INSTALL_DIR}/bin/mkldnn.dll >
+            ${MKLDNN_INSTALL_DIR}/bin/exports.txt
+    COMMAND echo LIBRARY mkldnn > ${MKLDNN_INSTALL_DIR}/bin/mkldnn.def
+    COMMAND echo EXPORTS >> ${MKLDNN_INSTALL_DIR}/bin/mkldnn.def
+    COMMAND
+      echo off && (for
+                   /f
+                   "skip=19 tokens=4"
+                   %A
+                   in
+                   (${MKLDNN_INSTALL_DIR}/bin/exports.txt)
+                   do
+                   echo
+                   %A
+                   >>
+                   ${MKLDNN_INSTALL_DIR}/bin/mkldnn.def) && echo on
+    COMMAND lib /def:${MKLDNN_INSTALL_DIR}/bin/mkldnn.def /out:${MKLDNN_LIB}
+            /machine:x64
+    COMMENT "Generate mkldnn.lib manually--->"
+    DEPENDS ${MKLDNN_PROJECT}
+    VERBATIM)
+  add_custom_target(mkldnn_cmd ALL DEPENDS ${MKLDNN_LIB})
+else()
+  set(MKLDNN_SHARED_LIB ${MKLDNN_INSTALL_DIR}/libmkldnn.so.0)
+  set(MKLDNN_SHARED_LIB_1 ${MKLDNN_INSTALL_DIR}/libdnnl.so.1)
+  set(MKLDNN_SHARED_LIB_2 ${MKLDNN_INSTALL_DIR}/libdnnl.so.2)
+  add_custom_command(
+    OUTPUT ${MKLDNN_SHARED_LIB_2}
+    COMMAND ${CMAKE_COMMAND} -E copy ${MKLDNN_LIB} ${MKLDNN_SHARED_LIB}
+    COMMAND ${CMAKE_COMMAND} -E copy ${MKLDNN_LIB} ${MKLDNN_SHARED_LIB_1}
+    COMMAND ${CMAKE_COMMAND} -E copy ${MKLDNN_LIB} ${MKLDNN_SHARED_LIB_2}
+    DEPENDS ${MKLDNN_PROJECT})
+  add_custom_target(mkldnn_cmd ALL DEPENDS ${MKLDNN_SHARED_LIB_2})
+endif()
+
+# generate a static dummy target to track mkldnn dependencies
+# for cc_library(xxx SRCS xxx.c DEPS mkldnn)
+generate_dummy_static_lib(LIB_NAME "mkldnn" GENERATOR "mkldnn.cmake")
+
+target_link_libraries(mkldnn ${MKLDNN_LIB} ${MKLML_IOMP_LIB})
+add_dependencies(mkldnn ${MKLDNN_PROJECT} mkldnn_cmd)

cmake/external/mklml.cmake

+# Copyright (c) 2017 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+include(ExternalProject)
+set(MKLML_INSTALL_DIR ${THIRD_PARTY_PATH}/install/mklml)
+set(MKLML_INC_DIR ${MKLML_INSTALL_DIR}/include)
+set(MKLML_LIB_DIR ${MKLML_INSTALL_DIR}/lib)
+set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_RPATH}" "${MKLML_LIB_DIR}")
+
+if(WIN32)
+  set(MKLML_VER
+      "mklml_win_2019.0.5.20190502"
+      CACHE STRING "" FORCE)
+  set(MKLML_URL
+      "https://paddlepaddledeps.bj.bcebos.com/${MKLML_VER}.zip"
+      CACHE STRING "" FORCE)
+  set(MKLML_URL_MD5 ff8c5237570f03eea37377ccfc95a08a)
+  set(MKLML_LIB ${MKLML_LIB_DIR}/mklml.lib)
+  set(MKLML_IOMP_LIB ${MKLML_LIB_DIR}/libiomp5md.lib)
+  set(MKLML_SHARED_LIB ${MKLML_LIB_DIR}/mklml.dll)
+  set(MKLML_SHARED_IOMP_LIB ${MKLML_LIB_DIR}/libiomp5md.dll)
+else()
+  #TODO(intel-huying):
+  #  Now enable csrmm function in mklml library temporarily,
+  #  it will be updated as offical version later.
+  set(MKLML_VER
+      "csrmm_mklml_lnx_2019.0.5"
+      CACHE STRING "" FORCE)
+  set(MKLML_URL
+      "http://paddlepaddledeps.bj.bcebos.com/${MKLML_VER}.tgz"
+      CACHE STRING "" FORCE)
+  set(MKLML_URL_MD5 bc6a7faea6a2a9ad31752386f3ae87da)
+  set(MKLML_LIB ${MKLML_LIB_DIR}/libmklml_intel.so)
+  set(MKLML_IOMP_LIB ${MKLML_LIB_DIR}/libiomp5.so)
+  set(MKLML_SHARED_LIB ${MKLML_LIB_DIR}/libmklml_intel.so)
+  set(MKLML_SHARED_IOMP_LIB ${MKLML_LIB_DIR}/libiomp5.so)
+endif()
+
+set(MKLML_PROJECT "extern_mklml")
+message(STATUS "MKLML_VER: ${MKLML_VER}, MKLML_URL: ${MKLML_URL}")
+set(MKLML_PREFIX_DIR ${THIRD_PARTY_PATH}/mklml)
+set(MKLML_SOURCE_DIR ${THIRD_PARTY_PATH}/mklml/src/extern_mklml)
+
+# Ninja Generator can not establish the correct dependency relationship
+# between the imported library with target, the product file
+# in the ExternalProject need to be specified manually, please refer to
+# https://stackoverflow.com/questions/54866067/cmake-and-ninja-missing-and-no-known-rule-to-make-it
+# It is the same to all other ExternalProject.
+ExternalProject_Add(
+  ${MKLML_PROJECT}
+  ${EXTERNAL_PROJECT_LOG_ARGS}
+  URL ${MKLML_URL}
+  URL_MD5 ${MKLML_URL_MD5}
+  PREFIX ${MKLML_PREFIX_DIR}
+  DOWNLOAD_NO_PROGRESS 1
+  CONFIGURE_COMMAND ""
+  BUILD_COMMAND ""
+  UPDATE_COMMAND ""
+  INSTALL_COMMAND
+    ${CMAKE_COMMAND} -E copy_directory ${MKLML_SOURCE_DIR}/include
+    ${MKLML_INC_DIR} && ${CMAKE_COMMAND} -E copy_directory
+    ${MKLML_SOURCE_DIR}/lib ${MKLML_LIB_DIR}
+  BUILD_BYPRODUCTS ${MKLML_LIB}
+  BUILD_BYPRODUCTS ${MKLML_IOMP_LIB})
+
+include_directories(${MKLML_INC_DIR})
+
+add_library(mklml SHARED IMPORTED GLOBAL)
+set_property(TARGET mklml PROPERTY IMPORTED_LOCATION ${MKLML_LIB})
+add_dependencies(mklml ${MKLML_PROJECT})

cmake/external/onnxruntime.cmake

+# Copyright (c) 2022 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+if(NOT WITH_ONNXRUNTIME)
+  return()
+endif()
+
+if(WITH_ARM)
+  message(SEND_ERROR "The current onnxruntime backend doesn't support ARM cpu")
+  return()
+endif()
+
+include(ExternalProject)
+
+add_definitions(-DPADDLE_WITH_ONNXRUNTIME)
+
+set(ONNXRUNTIME_PROJECT "extern_onnxruntime")
+set(ONNXRUNTIME_VERSION "1.11.1")
+set(ONNXRUNTIME_PREFIX_DIR ${THIRD_PARTY_PATH}/onnxruntime)
+set(ONNXRUNTIME_SOURCE_DIR
+    ${THIRD_PARTY_PATH}/onnxruntime/src/${ONNXRUNTIME_PROJECT})
+set(ONNXRUNTIME_INSTALL_DIR ${THIRD_PARTY_PATH}/install/onnxruntime)
+set(ONNXRUNTIME_INC_DIR
+    "${ONNXRUNTIME_INSTALL_DIR}/include"
+    CACHE PATH "onnxruntime include directory." FORCE)
+set(ONNXRUNTIME_LIB_DIR
+    "${ONNXRUNTIME_INSTALL_DIR}/lib"
+    CACHE PATH "onnxruntime lib directory." FORCE)
+set(CMAKE_BUILD_RPATH "${CMAKE_BUILD_RPATH}" "${ONNXRUNTIME_LIB_DIR}")
+
+if(WIN32)
+  set(ONNXRUNTIME_URL
+      "https://github.com/microsoft/onnxruntime/releases/download/v${ONNXRUNTIME_VERSION}/onnxruntime-win-x64-${ONNXRUNTIME_VERSION}.zip"
+  )
+elseif(APPLE)
+  set(ONNXRUNTIME_URL
+      "https://github.com/microsoft/onnxruntime/releases/download/v${ONNXRUNTIME_VERSION}/onnxruntime-osx-x86_64-${ONNXRUNTIME_VERSION}.tgz"
+  )
+else()
+  set(ONNXRUNTIME_URL
+      "https://github.com/microsoft/onnxruntime/releases/download/v${ONNXRUNTIME_VERSION}/onnxruntime-linux-x64-${ONNXRUNTIME_VERSION}.tgz"
+  )
+endif()
+
+# For ONNXRUNTIME code to include internal headers.
+include_directories(${ONNXRUNTIME_INC_DIR})
+
+set(ONNXRUNTIME_LIB_NEW_NAME "libonnxruntime${CMAKE_SHARED_LIBRARY_SUFFIX}")
+if(APPLE)
+  set(ONNXRUNTIME_LIB_NAME
+      "libonnxruntime.${ONNXRUNTIME_VERSION}${CMAKE_SHARED_LIBRARY_SUFFIX}")
+else()
+  set(ONNXRUNTIME_LIB_NAME
+      "libonnxruntime${CMAKE_SHARED_LIBRARY_SUFFIX}.${ONNXRUNTIME_VERSION}")
+endif()
+if(WIN32)
+  set(ONNXRUNTIME_SOURCE_LIB
+      "${ONNXRUNTIME_SOURCE_DIR}/lib/onnxruntime.dll"
+      CACHE FILEPATH "ONNXRUNTIME source library." FORCE)
+  set(ONNXRUNTIME_SHARED_LIB
+      "${ONNXRUNTIME_INSTALL_DIR}/lib/onnxruntime.dll"
+      CACHE FILEPATH "ONNXRUNTIME shared library." FORCE)
+  set(ONNXRUNTIME_LIB
+      "${ONNXRUNTIME_INSTALL_DIR}/lib/onnxruntime.lib"
+      CACHE FILEPATH "ONNXRUNTIME static library." FORCE)
+elseif(APPLE)
+  set(ONNXRUNTIME_SOURCE_LIB
+      "${ONNXRUNTIME_SOURCE_DIR}/lib/${ONNXRUNTIME_LIB_NAME}"
+      CACHE FILEPATH "ONNXRUNTIME source library." FORCE)
+  set(ONNXRUNTIME_LIB
+      "${ONNXRUNTIME_INSTALL_DIR}/lib/${ONNXRUNTIME_LIB_NAME}"
+      CACHE FILEPATH "ONNXRUNTIME static library." FORCE)
+  set(ONNXRUNTIME_SHARED_LIB
+      ${ONNXRUNTIME_LIB}
+      CACHE FILEPATH "ONNXRUNTIME shared library." FORCE)
+else()
+  set(ONNXRUNTIME_SOURCE_LIB
+      "${ONNXRUNTIME_SOURCE_DIR}/lib/${ONNXRUNTIME_LIB_NAME}"
+      CACHE FILEPATH "ONNXRUNTIME source library." FORCE)
+  set(ONNXRUNTIME_LIB
+      "${ONNXRUNTIME_INSTALL_DIR}/lib/${ONNXRUNTIME_LIB_NAME}"
+      CACHE FILEPATH "ONNXRUNTIME static library." FORCE)
+  set(ONNXRUNTIME_SHARED_LIB
+      ${ONNXRUNTIME_LIB}
+      CACHE FILEPATH "ONNXRUNTIME shared library." FORCE)
+endif()
+
+if(WIN32)
+  ExternalProject_Add(
+    ${ONNXRUNTIME_PROJECT}
+    ${EXTERNAL_PROJECT_LOG_ARGS}
+    URL ${ONNXRUNTIME_URL}
+    PREFIX ${ONNXRUNTIME_PREFIX_DIR}
+    DOWNLOAD_NO_PROGRESS 1
+    CONFIGURE_COMMAND ""
+    BUILD_COMMAND ""
+    UPDATE_COMMAND ""
+    INSTALL_COMMAND
+      ${CMAKE_COMMAND} -E copy ${ONNXRUNTIME_SOURCE_LIB}
+      ${ONNXRUNTIME_SHARED_LIB} && ${CMAKE_COMMAND} -E copy
+      ${ONNXRUNTIME_SOURCE_DIR}/lib/onnxruntime.lib ${ONNXRUNTIME_LIB} &&
+      ${CMAKE_COMMAND} -E copy_directory ${ONNXRUNTIME_SOURCE_DIR}/include
+      ${ONNXRUNTIME_INC_DIR}
+    BUILD_BYPRODUCTS ${ONNXRUNTIME_LIB})
+else()
+  ExternalProject_Add(
+    ${ONNXRUNTIME_PROJECT}
+    ${EXTERNAL_PROJECT_LOG_ARGS}
+    URL ${ONNXRUNTIME_URL}
+    PREFIX ${ONNXRUNTIME_PREFIX_DIR}
+    DOWNLOAD_NO_PROGRESS 1
+    CONFIGURE_COMMAND ""
+    BUILD_COMMAND ""
+    UPDATE_COMMAND ""
+    INSTALL_COMMAND
+      ${CMAKE_COMMAND} -E copy ${ONNXRUNTIME_SOURCE_LIB} ${ONNXRUNTIME_LIB} &&
+      ${CMAKE_COMMAND} -E copy_directory ${ONNXRUNTIME_SOURCE_DIR}/include
+      ${ONNXRUNTIME_INC_DIR} && ${CMAKE_COMMAND} -E create_symlink
+      ${ONNXRUNTIME_LIB_NAME} ${ONNXRUNTIME_LIB_DIR}/${ONNXRUNTIME_LIB_NEW_NAME}
+    BUILD_BYPRODUCTS ${ONNXRUNTIME_LIB})
+endif()
+
+add_library(onnxruntime STATIC IMPORTED GLOBAL)
+set_property(TARGET onnxruntime PROPERTY IMPORTED_LOCATION ${ONNXRUNTIME_LIB})
+add_dependencies(onnxruntime ${ONNXRUNTIME_PROJECT})
+
+function(copy_onnx TARGET_NAME)
+  # If error of Exitcode0xc000007b happened when a .exe running, copy onnxruntime.dll
+  # to the .exe folder.
+  if(TARGET ${TARGET_NAME})
+    add_custom_command(
+      TARGET ${TARGET_NAME}
+      POST_BUILD
+      COMMAND ${CMAKE_COMMAND} -E copy ${ONNXRUNTIME_SHARED_LIB}
+              ${CMAKE_CURRENT_BINARY_DIR} DEPENDS onnxruntime)
+  endif()
+endfunction()

cmake/external/openblas.cmake

+# Copyright (c) 2016 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+include(ExternalProject)
+
+set(CBLAS_PREFIX_DIR ${THIRD_PARTY_PATH}/openblas)
+set(CBLAS_INSTALL_DIR ${THIRD_PARTY_PATH}/install/openblas)
+set(CBLAS_REPOSITORY ${GIT_URL}/xianyi/OpenBLAS.git)
+set(CBLAS_TAG v0.3.7)
+if(APPLE AND WITH_ARM)
+  set(CBLAS_TAG v0.3.13)
+endif()
+
+if(WITH_MIPS)
+  set(CBLAS_TAG v0.3.13)
+endif()
+
+if(NOT WIN32)
+  set(CBLAS_LIBRARIES
+      "${CBLAS_INSTALL_DIR}/lib/${CMAKE_STATIC_LIBRARY_PREFIX}openblas${CMAKE_STATIC_LIBRARY_SUFFIX}"
+      CACHE FILEPATH "openblas library." FORCE)
+  set(CBLAS_INC_DIR
+      "${CBLAS_INSTALL_DIR}/include"
+      CACHE PATH "openblas include directory." FORCE)
+  set(OPENBLAS_CC
+      "${CMAKE_C_COMPILER} -Wno-unused-but-set-variable -Wno-unused-variable")
+
+  if(APPLE)
+    set(OPENBLAS_CC "${CMAKE_C_COMPILER} -isysroot ${CMAKE_OSX_SYSROOT}")
+  endif()
+  set(OPTIONAL_ARGS "")
+  if(CMAKE_SYSTEM_PROCESSOR MATCHES "^x86(_64)?$")
+    set(OPTIONAL_ARGS DYNAMIC_ARCH=1 NUM_THREADS=64)
+  endif()
+
+  set(COMMON_ARGS CC=${OPENBLAS_CC} NO_SHARED=1 NO_LAPACK=1 libs)
+  ExternalProject_Add(
+    extern_openblas
+    ${EXTERNAL_PROJECT_LOG_ARGS} ${SHALLOW_CLONE}
+    GIT_REPOSITORY ${CBLAS_REPOSITORY}
+    GIT_TAG ${CBLAS_TAG}
+    PREFIX ${CBLAS_PREFIX_DIR}
+    INSTALL_DIR ${CBLAS_INSTALL_DIR}
+    BUILD_IN_SOURCE 1
+    BUILD_COMMAND make -j${NPROC} ${COMMON_ARGS} ${OPTIONAL_ARGS}
+    INSTALL_COMMAND make install NO_SHARED=1 NO_LAPACK=1 PREFIX=<INSTALL_DIR>
+    UPDATE_COMMAND ""
+    CONFIGURE_COMMAND ""
+    BUILD_BYPRODUCTS ${CBLAS_LIBRARIES})
+else()
+  set(CBLAS_LIBRARIES
+      "${CBLAS_INSTALL_DIR}/lib/openblas${CMAKE_STATIC_LIBRARY_SUFFIX}"
+      CACHE FILEPATH "openblas library." FORCE)
+  set(CBLAS_INC_DIR
+      "${CBLAS_INSTALL_DIR}/include/openblas"
+      CACHE PATH "openblas include directory." FORCE)
+  ExternalProject_Add(
+    extern_openblas
+    ${EXTERNAL_PROJECT_LOG_ARGS}
+    GIT_REPOSITORY ${CBLAS_REPOSITORY}
+    GIT_TAG ${CBLAS_TAG}
+    PREFIX ${CBLAS_PREFIX_DIR}
+    INSTALL_DIR ${CBLAS_INSTALL_DIR}
+    BUILD_IN_SOURCE 0
+    UPDATE_COMMAND ""
+    CMAKE_ARGS -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
+               -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}
+               -DCMAKE_C_FLAGS=${CMAKE_C_FLAGS}
+               -DCMAKE_CXX_FLAGS=${CMAKE_CXX_FLAGS}
+               -DCMAKE_INSTALL_PREFIX=${CBLAS_INSTALL_DIR}
+               -DCMAKE_POSITION_INDEPENDENT_CODE=ON
+               -DCMAKE_BUILD_TYPE=${THIRD_PARTY_BUILD_TYPE}
+               -DBUILD_SHARED_LIBS=ON
+               -DMSVC_STATIC_CRT=${MSVC_STATIC_CRT}
+               ${EXTERNAL_OPTIONAL_ARGS}
+    CMAKE_CACHE_ARGS
+      -DCMAKE_INSTALL_PREFIX:PATH=${CBLAS_INSTALL_DIR}
+      -DCMAKE_POSITION_INDEPENDENT_CODE:BOOL=ON
+      -DCMAKE_BUILD_TYPE:STRING=${THIRD_PARTY_BUILD_TYPE}
+    # ninja need to know where openblas.lib comes from
+    BUILD_BYPRODUCTS ${CBLAS_LIBRARIES})
+  set(OPENBLAS_SHARED_LIB
+      ${CBLAS_INSTALL_DIR}/bin/openblas${CMAKE_SHARED_LIBRARY_SUFFIX})
+endif()

cmake/external/paddle2onnx.cmake

+# Copyright (c) 2022 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+if(NOT WITH_ONNXRUNTIME)
+  return()
+endif()
+
+if(WITH_ARM)
+  message(SEND_ERROR "The current onnxruntime backend doesn't support ARM cpu")
+  return()
+endif()
+
+include(ExternalProject)
+
+set(PADDLE2ONNX_PROJECT "extern_paddle2onnx")
+set(PADDLE2ONNX_VERSION "1.0.0rc2")
+set(PADDLE2ONNX_PREFIX_DIR ${THIRD_PARTY_PATH}/paddle2onnx)
+set(PADDLE2ONNX_SOURCE_DIR
+    ${THIRD_PARTY_PATH}/paddle2onnx/src/${PADDLE2ONNX_PROJECT})
+set(PADDLE2ONNX_INSTALL_DIR ${THIRD_PARTY_PATH}/install/paddle2onnx)
+set(PADDLE2ONNX_INC_DIR
+    "${PADDLE2ONNX_INSTALL_DIR}/include"
+    CACHE PATH "paddle2onnx include directory." FORCE)
+set(PADDLE2ONNX_LIB_DIR
+    "${PADDLE2ONNX_INSTALL_DIR}/lib"
+    CACHE PATH "onnxruntime lib directory." FORCE)
+set(CMAKE_BUILD_RPATH "${CMAKE_BUILD_RPATH}" "${PADDLE2ONNX_LIB_DIR}")
+
+# For PADDLE2ONNX code to include internal headers.
+include_directories(${PADDLE2ONNX_INC_DIR})
+set(PADDLE2ONNX_LIB_NEW_NAME "libpaddle2onnx${CMAKE_SHARED_LIBRARY_SUFFIX}")
+if(APPLE)
+  set(PADDLE2ONNX_LIB_NAME
+      "libpaddle2onnx.${PADDLE2ONNX_VERSION}${CMAKE_SHARED_LIBRARY_SUFFIX}")
+else()
+  set(PADDLE2ONNX_LIB_NAME
+      "libpaddle2onnx${CMAKE_SHARED_LIBRARY_SUFFIX}.${PADDLE2ONNX_VERSION}")
+endif()
+
+if(WIN32)
+  set(PADDLE2ONNX_LIB
+      "${PADDLE2ONNX_INSTALL_DIR}/lib/paddle2onnx.dll"
+      CACHE FILEPATH "paddle2onnx library." FORCE)
+  set(PADDLE2ONNX_COMPILE_LIB
+      "${PADDLE2ONNX_INSTALL_DIR}/lib/paddle2onnx.lib"
+      CACHE FILEPATH "paddle2onnx compile library." FORCE)
+else()
+  set(PADDLE2ONNX_SOURCE_LIB
+      "${PADDLE2ONNX_SOURCE_DIR}/lib/${PADDLE2ONNX_LIB_NAME}"
+      CACHE FILEPATH "PADDLE2ONNX source library." FORCE)
+  set(PADDLE2ONNX_LIB
+      "${PADDLE2ONNX_LIB_DIR}/${PADDLE2ONNX_LIB_NAME}"
+      CACHE FILEPATH "PADDLE2ONNX library." FORCE)
+  set(PADDLE2ONNX_COMPILE_LIB
+      ${PADDLE2ONNX_LIB}
+      CACHE FILEPATH "paddle2onnx compile library." FORCE)
+endif()
+
+if(WIN32)
+  set(PADDLE2ONNX_URL
+      "https://github.com/PaddlePaddle/Paddle2ONNX/releases/download/v${PADDLE2ONNX_VERSION}/paddle2onnx-win-x64-${PADDLE2ONNX_VERSION}.zip"
+  )
+elseif(APPLE)
+  set(PADDLE2ONNX_URL
+      "https://github.com/PaddlePaddle/Paddle2ONNX/releases/download/v${PADDLE2ONNX_VERSION}/paddle2onnx-osx-x86_64-${PADDLE2ONNX_VERSION}.tgz"
+  )
+else()
+  set(PADDLE2ONNX_URL
+      "https://github.com/PaddlePaddle/Paddle2ONNX/releases/download/v${PADDLE2ONNX_VERSION}/paddle2onnx-linux-x64-${PADDLE2ONNX_VERSION}.tgz"
+  )
+endif()
+
+if(WIN32)
+  ExternalProject_Add(
+    ${PADDLE2ONNX_PROJECT}
+    ${EXTERNAL_PROJECT_LOG_ARGS}
+    URL ${PADDLE2ONNX_URL}
+    PREFIX ${PADDLE2ONNX_PREFIX_DIR}
+    DOWNLOAD_NO_PROGRESS 1
+    CONFIGURE_COMMAND ""
+    BUILD_COMMAND ""
+    UPDATE_COMMAND ""
+    INSTALL_COMMAND
+      ${CMAKE_COMMAND} -E copy_directory ${PADDLE2ONNX_SOURCE_DIR}/lib
+      ${PADDLE2ONNX_LIB_DIR} && ${CMAKE_COMMAND} -E copy_directory
+      ${PADDLE2ONNX_SOURCE_DIR}/include ${PADDLE2ONNX_INC_DIR}
+    BUILD_BYPRODUCTS ${PADDLE2ONNX_COMPILE_LIB})
+else()
+  ExternalProject_Add(
+    ${PADDLE2ONNX_PROJECT}
+    ${EXTERNAL_PROJECT_LOG_ARGS}
+    URL ${PADDLE2ONNX_URL}
+    PREFIX ${PADDLE2ONNX_PREFIX_DIR}
+    DOWNLOAD_NO_PROGRESS 1
+    CONFIGURE_COMMAND ""
+    BUILD_COMMAND ""
+    UPDATE_COMMAND ""
+    INSTALL_COMMAND
+      ${CMAKE_COMMAND} -E copy ${PADDLE2ONNX_SOURCE_LIB}
+      ${PADDLE2ONNX_COMPILE_LIB} && ${CMAKE_COMMAND} -E copy_directory
+      ${PADDLE2ONNX_SOURCE_DIR}/include ${PADDLE2ONNX_INC_DIR} &&
+      ${CMAKE_COMMAND} -E create_symlink ${PADDLE2ONNX_LIB_NAME}
+      ${PADDLE2ONNX_LIB_DIR}/${PADDLE2ONNX_LIB_NEW_NAME}
+    BUILD_BYPRODUCTS ${PADDLE2ONNX_COMPILE_LIB})
+endif()
+
+add_library(paddle2onnx STATIC IMPORTED GLOBAL)
+set_property(TARGET paddle2onnx PROPERTY IMPORTED_LOCATION
+                                         ${PADDLE2ONNX_COMPILE_LIB})
+add_dependencies(paddle2onnx ${PADDLE2ONNX_PROJECT})

cmake/external/pocketfft.cmake

+# Copyright (c) 2018 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+include(ExternalProject)
+
+set(POCKETFFT_PATH
+    "${THIRD_PARTY_PATH}/pocketfft"
+    CACHE STRING "A path setting for external_pocketfft path.")
+set(POCKETFFT_PREFIX_DIR ${POCKETFFT_PATH})
+
+set(POCKETFFT_REPOSITORY https://gitlab.mpcdf.mpg.de/mtr/pocketfft.git)
+set(POCKETFFT_TAG release_for_eigen)
+
+set(POCKETFFT_INCLUDE_DIR ${POCKETFFT_PREFIX_DIR}/src)
+message("POCKETFFT_INCLUDE_DIR is ${POCKETFFT_INCLUDE_DIR}")
+include_directories(${POCKETFFT_INCLUDE_DIR})
+
+ExternalProject_Add(
+  extern_pocketfft
+  ${EXTERNAL_PROJECT_LOG_ARGS} ${SHALLOW_CLONE}
+  GIT_REPOSITORY ${POCKETFFT_REPOSITORY}
+  GIT_TAG ${POCKETFFT_TAG}
+  PREFIX ${POCKETFFT_PREFIX_DIR}
+  UPDATE_COMMAND ""
+  CONFIGURE_COMMAND ""
+  BUILD_COMMAND ""
+  INSTALL_COMMAND ""
+  TEST_COMMAND "")
+
+add_library(pocketfft INTERFACE)
+
+add_dependencies(pocketfft extern_pocketfft)

cmake/external/poplar.cmake

+# Copyright (c) 2021 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+macro(find_popart_version popart_version_file)
+  file(READ ${popart_version_file} popart_version_file_content)
+  string(
+    REGEX
+      MATCH
+      "(POPART_VERSION_STRING)[ \t\r\n](\")([0-9]+\.[0-9]+\.[0-9]+)(\\+)([A-Za-z0-9_]*)(\")"
+      POPART_VERSION
+      ${popart_version_file_content})
+  string(REPLACE "POPART_VERSION_STRING" "" POPART_VERSION "${POPART_VERSION}")
+  string(REPLACE "\"" "" POPART_VERSION "${POPART_VERSION}")
+  string(REPLACE " " "" POPART_VERSION "${POPART_VERSION}")
+  if(NOT POPART_VERSION)
+    set(POPART_VERSION "Unknown version")
+  else()
+    message(STATUS "Current PopART version is ${POPART_VERSION}")
+  endif()
+endmacro()
+
+if(WITH_IPU)
+  set(POPLAR_DIR CACHE PATH "Path to a Poplar install")
+  set(POPART_DIR CACHE PATH "Path to a Popart install")
+  set(POPLAR_SDK_DIR
+      CACHE
+        PATH
+        "Path to an extracted SDK archive or to a Poplar & Popart install directory (Will populate POPLAR_DIR and POPART_DIR)"
+  )
+
+  # support setting SDK both from environment variable or command line arguments
+
+  if(DEFINED ENV{POPLAR_SDK_DIR})
+    set(POPLAR_SDK_DIR $ENV{POPLAR_SDK_DIR})
+  endif()
+  if(EXISTS ${POPLAR_SDK_DIR})
+    execute_process(
+      COMMAND find ${POPLAR_SDK_DIR}/ -maxdepth 1 -type d -name "popart*"
+      OUTPUT_VARIABLE POPART_DIR
+      OUTPUT_STRIP_TRAILING_WHITESPACE)
+    execute_process(
+      COMMAND find ${POPLAR_SDK_DIR}/ -maxdepth 1 -type d -name "poplar-*" -o
+              -name "poplar"
+      OUTPUT_VARIABLE POPLAR_DIR
+      OUTPUT_STRIP_TRAILING_WHITESPACE)
+  endif()
+  if(DEFINED ENV{POPLAR_DIR})
+    set(POPLAR_DIR $ENV{POPLAR_DIR})
+  endif()
+  if(DEFINED ENV{POPART_DIR})
+    set(POPART_DIR $ENV{POPART_DIR})
+  endif()
+
+  if(EXISTS ${POPLAR_DIR})
+    message("POPLAR_DIR is ${POPLAR_DIR}")
+    if(NOT IS_DIRECTORY "${POPLAR_DIR}")
+      message(
+        FATAL_ERROR
+          "Couldn't find a \"poplar\" or \"poplar-*\" folder in '${POPLAR_SDK_DIR}'"
+      )
+    endif()
+    list(APPEND CMAKE_PREFIX_PATH ${POPLAR_DIR})
+    set(ENABLE_POPLAR_CMD "source ${POPLAR_DIR}/enable.sh")
+    find_package(poplar REQUIRED)
+    include_directories("${POPLAR_DIR}/include")
+    link_directories("${POPLAR_DIR}/lib")
+  endif()
+  if(NOT poplar_FOUND)
+    message(
+      FATAL_ERROR
+        "You must provide a path to a Poplar install using -DPOPLAR_DIR=/path/to/popart/build/install"
+    )
+  endif()
+  if(EXISTS ${POPART_DIR})
+    message("POPART_DIR is ${POPART_DIR}")
+    if(NOT IS_DIRECTORY "${POPART_DIR}")
+      message(
+        FATAL_ERROR "Couldn't find a \"popart*\" folder in '${POPLAR_SDK_DIR}'")
+    endif()
+    list(APPEND CMAKE_PREFIX_PATH ${POPART_DIR})
+    set(ENABLE_POPART_CMD "source ${POPART_DIR}/enable.sh")
+    find_package(popart REQUIRED COMPONENTS popart-only)
+    include_directories("${POPART_DIR}/include")
+    link_directories("${POPART_DIR}/lib")
+  endif()
+  if(NOT popart_FOUND)
+    message(
+      FATAL_ERROR
+        "You must provide a path to a Popart build using -DPOPART_DIR=/path/to/popart/build"
+    )
+  endif()
+
+  find_popart_version("${POPART_DIR}/include/popart/version.hpp")
+
+  add_definitions(-DONNX_NAMESPACE=onnx)
+  add_custom_target(extern_poplar DEPENDS poplar popart-only)
+endif()

cmake/external/protobuf.cmake

+# Copyright (c) 2016 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+include(ExternalProject)
+# Always invoke `FIND_PACKAGE(Protobuf)` for importing function protobuf_generate_cpp
+if(NOT WIN32)
+  find_package(Protobuf QUIET)
+endif()
+
+unset_var(PROTOBUF_INCLUDE_DIR)
+unset_var(PROTOBUF_FOUND)
+unset_var(PROTOBUF_PROTOC_EXECUTABLE)
+unset_var(PROTOBUF_PROTOC_LIBRARY)
+unset_var(PROTOBUF_LITE_LIBRARY)
+unset_var(PROTOBUF_LIBRARY)
+unset_var(PROTOBUF_INCLUDE_DIR)
+unset_var(Protobuf_PROTOC_EXECUTABLE)
+function(protobuf_generate_python SRCS)
+  # shameless copy from https://github.com/Kitware/CMake/blob/master/Modules/FindProtobuf.cmake
+  if(NOT ARGN)
+    message(
+      SEND_ERROR
+        "Error: PROTOBUF_GENERATE_PYTHON() called without any proto files")
+    return()
+  endif()
+
+  if(PROTOBUF_GENERATE_CPP_APPEND_PATH)
+    # Create an include path for each file specified
+    foreach(FIL ${ARGN})
+      get_filename_component(ABS_FIL ${FIL} ABSOLUTE)
+      get_filename_component(ABS_PATH ${ABS_FIL} PATH)
+      list(FIND _protobuf_include_path ${ABS_PATH} _contains_already)
+      if(${_contains_already} EQUAL -1)
+        list(APPEND _protobuf_include_path -I ${ABS_PATH})
+      endif()
+    endforeach()
+  else()
+    set(_protobuf_include_path -I ${CMAKE_CURRENT_SOURCE_DIR})
+  endif()
+  if(DEFINED PROTOBUF_IMPORT_DIRS AND NOT DEFINED Protobuf_IMPORT_DIRS)
+    set(Protobuf_IMPORT_DIRS "${PROTOBUF_IMPORT_DIRS}")
+  endif()
+
+  if(DEFINED Protobuf_IMPORT_DIRS)
+    foreach(DIR ${Protobuf_IMPORT_DIRS})
+      get_filename_component(ABS_PATH ${DIR} ABSOLUTE)
+      list(FIND _protobuf_include_path ${ABS_PATH} _contains_already)
+      if(${_contains_already} EQUAL -1)
+        list(APPEND _protobuf_include_path -I ${ABS_PATH})
+      endif()
+    endforeach()
+  endif()
+
+  set(${SRCS})
+  foreach(FIL ${ARGN})
+    get_filename_component(ABS_FIL ${FIL} ABSOLUTE)
+    get_filename_component(FIL_WE ${FIL} NAME_WE)
+    if(NOT PROTOBUF_GENERATE_CPP_APPEND_PATH)
+      get_filename_component(FIL_DIR ${FIL} DIRECTORY)
+      if(FIL_DIR)
+        set(FIL_WE "${FIL_DIR}/${FIL_WE}")
+      endif()
+    endif()
+    list(APPEND ${SRCS} "${CMAKE_CURRENT_BINARY_DIR}/${FIL_WE}_pb2.py")
+    add_custom_command(
+      OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${FIL_WE}_pb2.py"
+      COMMAND ${PROTOBUF_PROTOC_EXECUTABLE} --python_out
+              ${CMAKE_CURRENT_BINARY_DIR} ${_protobuf_include_path} ${ABS_FIL}
+      DEPENDS ${ABS_FIL} ${PROTOBUF_PROTOC_EXECUTABLE}
+      COMMENT "Running Python protocol buffer compiler on ${FIL}"
+      VERBATIM)
+  endforeach()
+
+  set(${SRCS}
+      ${${SRCS}}
+      PARENT_SCOPE)
+endfunction()
+
+# Print and set the protobuf library information,
+# finish this cmake process and exit from this file.
+macro(PROMPT_PROTOBUF_LIB)
+  set(protobuf_DEPS ${ARGN})
+
+  message(STATUS "Protobuf protoc executable: ${PROTOBUF_PROTOC_EXECUTABLE}")
+  message(STATUS "Protobuf-lite library: ${PROTOBUF_LITE_LIBRARY}")
+  message(STATUS "Protobuf library: ${PROTOBUF_LIBRARY}")
+  message(STATUS "Protoc library: ${PROTOBUF_PROTOC_LIBRARY}")
+  message(STATUS "Protobuf version: ${PROTOBUF_VERSION}")
+  include_directories(${PROTOBUF_INCLUDE_DIR})
+
+  # Assuming that all the protobuf libraries are of the same type.
+  if(${PROTOBUF_LIBRARY} MATCHES ${CMAKE_STATIC_LIBRARY_SUFFIX})
+    set(protobuf_LIBTYPE STATIC)
+  elseif(${PROTOBUF_LIBRARY} MATCHES "${CMAKE_SHARED_LIBRARY_SUFFIX}$")
+    set(protobuf_LIBTYPE SHARED)
+  else()
+    message(FATAL_ERROR "Unknown library type: ${PROTOBUF_LIBRARY}")
+  endif()
+
+  add_library(protobuf ${protobuf_LIBTYPE} IMPORTED GLOBAL)
+  set_property(TARGET protobuf PROPERTY IMPORTED_LOCATION ${PROTOBUF_LIBRARY})
+
+  add_library(protobuf_lite ${protobuf_LIBTYPE} IMPORTED GLOBAL)
+  set_property(TARGET protobuf_lite PROPERTY IMPORTED_LOCATION
+                                             ${PROTOBUF_LITE_LIBRARY})
+
+  add_library(libprotoc ${protobuf_LIBTYPE} IMPORTED GLOBAL)
+  set_property(TARGET libprotoc PROPERTY IMPORTED_LOCATION ${PROTOC_LIBRARY})
+
+  add_executable(protoc IMPORTED GLOBAL)
+  set_property(TARGET protoc PROPERTY IMPORTED_LOCATION
+                                      ${PROTOBUF_PROTOC_EXECUTABLE})
+  # FIND_Protobuf.cmake uses `Protobuf_PROTOC_EXECUTABLE`.
+  # make `protobuf_generate_cpp` happy.
+  set(Protobuf_PROTOC_EXECUTABLE ${PROTOBUF_PROTOC_EXECUTABLE})
+
+  foreach(dep ${protobuf_DEPS})
+    add_dependencies(protobuf ${dep})
+    add_dependencies(protobuf_lite ${dep})
+    add_dependencies(libprotoc ${dep})
+    add_dependencies(protoc ${dep})
+  endforeach()
+
+  return()
+endmacro()
+macro(SET_PROTOBUF_VERSION)
+  exec_program(
+    ${PROTOBUF_PROTOC_EXECUTABLE} ARGS
+    --version
+    OUTPUT_VARIABLE PROTOBUF_VERSION)
+  string(REGEX MATCH "[0-9]+.[0-9]+" PROTOBUF_VERSION "${PROTOBUF_VERSION}")
+endmacro()
+
+set(PROTOBUF_ROOT
+    ""
+    CACHE PATH "Folder contains protobuf")
+if(WIN32)
+  set(PROTOBUF_ROOT ${THIRD_PARTY_PATH}/install/protobuf)
+endif()
+
+if(NOT "${PROTOBUF_ROOT}" STREQUAL "")
+  find_path(
+    PROTOBUF_INCLUDE_DIR google/protobuf/message.h
+    PATHS ${PROTOBUF_ROOT}/include
+    NO_DEFAULT_PATH)
+  find_library(
+    PROTOBUF_LIBRARY protobuf libprotobuf.lib
+    PATHS ${PROTOBUF_ROOT}/lib
+    NO_DEFAULT_PATH)
+  find_library(
+    PROTOBUF_LITE_LIBRARY protobuf-lite libprotobuf-lite.lib
+    PATHS ${PROTOBUF_ROOT}/lib
+    NO_DEFAULT_PATH)
+  find_library(
+    PROTOBUF_PROTOC_LIBRARY protoc libprotoc.lib
+    PATHS ${PROTOBUF_ROOT}/lib
+    NO_DEFAULT_PATH)
+  find_program(
+    PROTOBUF_PROTOC_EXECUTABLE protoc
+    PATHS ${PROTOBUF_ROOT}/bin
+    NO_DEFAULT_PATH)
+  if(PROTOBUF_INCLUDE_DIR
+     AND PROTOBUF_LIBRARY
+     AND PROTOBUF_LITE_LIBRARY
+     AND PROTOBUF_PROTOC_LIBRARY
+     AND PROTOBUF_PROTOC_EXECUTABLE)
+    set(PROTOBUF_FOUND true)
+    message(STATUS "Using custom protobuf library in ${PROTOBUF_ROOT}.")
+    set_protobuf_version()
+    prompt_protobuf_lib()
+  endif()
+endif()
+
+function(build_protobuf TARGET_NAME BUILD_FOR_HOST)
+  string(REPLACE "extern_" "" TARGET_DIR_NAME "${TARGET_NAME}")
+  set(PROTOBUF_PREFIX_DIR ${THIRD_PARTY_PATH}/${TARGET_DIR_NAME})
+  set(PROTOBUF_SOURCE_DIR
+      ${THIRD_PARTY_PATH}/${TARGET_DIR_NAME}/src/${TARGET_NAME})
+  set(PROTOBUF_INSTALL_DIR ${THIRD_PARTY_PATH}/install/${TARGET_DIR_NAME})
+
+  set(${TARGET_NAME}_INCLUDE_DIR
+      "${PROTOBUF_INSTALL_DIR}/include"
+      PARENT_SCOPE)
+  set(PROTOBUF_INCLUDE_DIR
+      "${PROTOBUF_INSTALL_DIR}/include"
+      PARENT_SCOPE)
+  set(${TARGET_NAME}_LITE_LIBRARY
+      "${PROTOBUF_INSTALL_DIR}/lib/libprotobuf-lite${CMAKE_STATIC_LIBRARY_SUFFIX}"
+      PARENT_SCOPE)
+  set(${TARGET_NAME}_LIBRARY
+      "${PROTOBUF_INSTALL_DIR}/lib/libprotobuf${CMAKE_STATIC_LIBRARY_SUFFIX}"
+      PARENT_SCOPE)
+  set(${TARGET_NAME}_PROTOC_LIBRARY
+      "${PROTOBUF_INSTALL_DIR}/lib/libprotoc${CMAKE_STATIC_LIBRARY_SUFFIX}"
+      PARENT_SCOPE)
+  set(${TARGET_NAME}_PROTOC_EXECUTABLE
+      "${PROTOBUF_INSTALL_DIR}/bin/protoc${CMAKE_EXECUTABLE_SUFFIX}"
+      PARENT_SCOPE)
+
+  set(OPTIONAL_CACHE_ARGS "")
+  set(OPTIONAL_ARGS "")
+  if(BUILD_FOR_HOST)
+    set(OPTIONAL_ARGS "-Dprotobuf_WITH_ZLIB=OFF")
+  else()
+    set(OPTIONAL_ARGS
+        "-DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}"
+        "-DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}"
+        "-DCMAKE_C_FLAGS=${CMAKE_C_FLAGS}"
+        "-DCMAKE_C_FLAGS_DEBUG=${CMAKE_C_FLAGS_DEBUG}"
+        "-DCMAKE_C_FLAGS_RELEASE=${CMAKE_C_FLAGS_RELEASE}"
+        "-DCMAKE_CXX_FLAGS=${CMAKE_CXX_FLAGS}"
+        "-DCMAKE_CXX_FLAGS_RELEASE=${CMAKE_CXX_FLAGS_RELEASE}"
+        "-DCMAKE_CXX_FLAGS_DEBUG=${CMAKE_CXX_FLAGS_DEBUG}"
+        "-Dprotobuf_WITH_ZLIB=ON"
+        "-DZLIB_ROOT:FILEPATH=${ZLIB_ROOT}"
+        ${EXTERNAL_OPTIONAL_ARGS})
+    set(OPTIONAL_CACHE_ARGS "-DZLIB_ROOT:STRING=${ZLIB_ROOT}")
+  endif()
+  if(WIN32)
+    set(OPTIONAL_ARGS
+        ${OPTIONAL_ARGS} "-DCMAKE_GENERATOR=${CMAKE_GENERATOR}"
+        "-DCMAKE_GENERATOR_PLATFORM=${CMAKE_GENERATOR_PLATFORM}"
+        "-Dprotobuf_MSVC_STATIC_RUNTIME=${MSVC_STATIC_CRT}")
+  endif()
+
+  if(WITH_ASCEND AND NOT WITH_ASCEND_CXX11)
+    set(PROTOBUF_REPOSITORY https://gitee.com/tianjianhe/protobuf.git)
+    set(PROTOBUF_TAG v3.8.0)
+  elseif(WITH_ASCEND_CL AND NOT WITH_ASCEND_CXX11)
+    set(PROTOBUF_REPOSITORY https://gitee.com/tianjianhe/protobuf.git)
+    set(PROTOBUF_TAG v3.8.0)
+  elseif(WITH_IPU)
+    set(PROTOBUF_REPOSITORY ${GIT_URL}/protocolbuffers/protobuf.git)
+    set(PROTOBUF_TAG d750fbf648256c7c631f51ffdbf67d7c18b0114e)
+  elseif(WIN32)
+    set(PROTOBUF_REPOSITORY ${GIT_URL}/protocolbuffers/protobuf.git)
+    # Change the tag to support building with vs2019
+    set(PROTOBUF_TAG 01a05a53f40ca2ac5f0af10c6cc0810bee39b792)
+  else()
+    set(PROTOBUF_REPOSITORY ${GIT_URL}/protocolbuffers/protobuf.git)
+    set(PROTOBUF_TAG 9f75c5aa851cd877fb0d93ccc31b8567a6706546)
+  endif()
+  if(WITH_ARM_BRPC)
+    set(ARM_PROTOBUF_URL
+        "https://paddlerec.bj.bcebos.com/online_infer/arm_brpc_ubuntu18/arm_protobuf.tar.gz"
+        CACHE STRING "" FORCE)
+    file(
+      WRITE ${PROTOBUF_SOURCE_DIR}/CMakeLists.txt
+      "PROJECT(ARM_PROTOBUF)\n"
+      "cmake_minimum_required(VERSION 3.0)\n"
+      "install(DIRECTORY arm_protobuf/bin  arm_protobuf/include arm_protobuf/lib \n"
+      "        DESTINATION . USE_SOURCE_PERMISSIONS)\n")
+    ExternalProject_Add(
+      ${TARGET_NAME}
+      ${EXTERNAL_PROJECT_LOG_ARGS} ${SHALLOW_CLONE}
+      PREFIX ${PROTOBUF_PREFIX_DIR}
+      DOWNLOAD_DIR ${PROTOBUF_SOURCE_DIR}
+      DOWNLOAD_COMMAND rm -rf arm_protobuf.tar.gz && wget --no-check-certificate
+                       ${ARM_PROTOBUF_URL} && tar zxvf arm_protobuf.tar.gz
+      UPDATE_COMMAND ""
+      CMAKE_ARGS -DCMAKE_INSTALL_PREFIX:PATH=${PROTOBUF_INSTALL_DIR}
+                 -DCMAKE_BUILD_TYPE:STRING=${THIRD_PARTY_BUILD_TYPE}
+      CMAKE_CACHE_ARGS -DCMAKE_INSTALL_PREFIX:PATH=${PROTOBUF_INSTALL_DIR}
+                       -DCMAKE_BUILD_TYPE:STRING=${THIRD_PARTY_BUILD_TYPE}
+      BUILD_BYPRODUCTS
+        ${PROTOBUF_INSTALL_DIR}/lib/libprotobuf${CMAKE_STATIC_LIBRARY_SUFFIX}
+      BUILD_BYPRODUCTS
+        ${PROTOBUF_INSTALL_DIR}/lib/libprotobuf-lite${CMAKE_STATIC_LIBRARY_SUFFIX}
+      BUILD_BYPRODUCTS
+        ${PROTOBUF_INSTALL_DIR}/lib/libprotoc${CMAKE_STATIC_LIBRARY_SUFFIX}
+      BUILD_BYPRODUCTS
+        ${PROTOBUF_INSTALL_DIR}/bin/protoc${CMAKE_EXECUTABLE_SUFFIX})
+  else()
+    ExternalProject_Add(
+      ${TARGET_NAME}
+      ${EXTERNAL_PROJECT_LOG_ARGS} ${SHALLOW_CLONE}
+      GIT_REPOSITORY ${PROTOBUF_REPOSITORY}
+      GIT_TAG ${PROTOBUF_TAG}
+      PREFIX ${PROTOBUF_PREFIX_DIR}
+      UPDATE_COMMAND ""
+      DEPENDS zlib
+      CONFIGURE_COMMAND
+        ${CMAKE_COMMAND} ${PROTOBUF_SOURCE_DIR}/cmake ${OPTIONAL_ARGS}
+        -Dprotobuf_BUILD_TESTS=OFF -DCMAKE_SKIP_RPATH=ON
+        -DCMAKE_POSITION_INDEPENDENT_CODE=ON
+        -DCMAKE_BUILD_TYPE=${THIRD_PARTY_BUILD_TYPE}
+        -DCMAKE_INSTALL_PREFIX=${PROTOBUF_INSTALL_DIR}
+        -DCMAKE_INSTALL_LIBDIR=lib -DBUILD_SHARED_LIBS=OFF
+      CMAKE_CACHE_ARGS
+        -DCMAKE_INSTALL_PREFIX:PATH=${PROTOBUF_INSTALL_DIR}
+        -DCMAKE_BUILD_TYPE:STRING=${THIRD_PARTY_BUILD_TYPE}
+        -DCMAKE_VERBOSE_MAKEFILE:BOOL=OFF
+        -DCMAKE_POSITION_INDEPENDENT_CODE:BOOL=ON
+        ${OPTIONAL_CACHE_ARGS}
+      BUILD_BYPRODUCTS
+        ${PROTOBUF_INSTALL_DIR}/lib/libprotobuf${CMAKE_STATIC_LIBRARY_SUFFIX}
+      BUILD_BYPRODUCTS
+        ${PROTOBUF_INSTALL_DIR}/lib/libprotobuf-lite${CMAKE_STATIC_LIBRARY_SUFFIX}
+      BUILD_BYPRODUCTS
+        ${PROTOBUF_INSTALL_DIR}/lib/libprotoc${CMAKE_STATIC_LIBRARY_SUFFIX}
+      BUILD_BYPRODUCTS
+        ${PROTOBUF_INSTALL_DIR}/bin/protoc${CMAKE_EXECUTABLE_SUFFIX})
+  endif()
+endfunction()
+
+if(WITH_ASCEND OR WITH_ASCEND_CL)
+  set(PROTOBUF_VERSION 3.8.0)
+elseif(WITH_IPU)
+  set(PROTOBUF_VERSION 3.6.1)
+elseif(WITH_ARM_BRPC)
+  set(PROTOBUF_VERSION 3.7.1-baidu-ee-common)
+else()
+  set(PROTOBUF_VERSION 3.1.0)
+endif()
+
+if(NOT PROTOBUF_FOUND)
+  build_protobuf(extern_protobuf FALSE)
+
+  set(PROTOBUF_INCLUDE_DIR
+      ${extern_protobuf_INCLUDE_DIR}
+      CACHE PATH "protobuf include directory." FORCE)
+  set(PROTOBUF_LITE_LIBRARY
+      ${extern_protobuf_LITE_LIBRARY}
+      CACHE FILEPATH "protobuf lite library." FORCE)
+  set(PROTOBUF_LIBRARY
+      ${extern_protobuf_LIBRARY}
+      CACHE FILEPATH "protobuf library." FORCE)
+  set(PROTOBUF_PROTOC_LIBRARY
+      ${extern_protobuf_PROTOC_LIBRARY}
+      CACHE FILEPATH "protoc library." FORCE)
+
+  set(PROTOBUF_PROTOC_EXECUTABLE
+      ${extern_protobuf_PROTOC_EXECUTABLE}
+      CACHE FILEPATH "protobuf executable." FORCE)
+  # `EXTERN_PROTOBUF_DEPEND` used in cmake function `proto_library` to ensure
+  # `protoc.exe` existed before calling it.
+  set(EXTERN_PROTOBUF_DEPEND extern_protobuf)
+  prompt_protobuf_lib(extern_protobuf)
+endif()

cmake/external/pslib.cmake

+# Copyright (c) 2018 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+include(ExternalProject)
+
+set(PSLIB_PROJECT "extern_pslib")
+if((NOT DEFINED PSLIB_VER) OR (NOT DEFINED PSLIB_URL))
+  message(STATUS "use pre defined download url")
+  set(PSLIB_VER
+      "0.1.1"
+      CACHE STRING "" FORCE)
+  set(PSLIB_NAME
+      "pslib"
+      CACHE STRING "" FORCE)
+  set(PSLIB_URL
+      "https://pslib.bj.bcebos.com/pslib.tar.gz"
+      CACHE STRING "" FORCE)
+endif()
+message(STATUS "PSLIB_NAME: ${PSLIB_NAME}, PSLIB_URL: ${PSLIB_URL}")
+set(PSLIB_PREFIX_DIR "${THIRD_PARTY_PATH}/pslib")
+set(PSLIB_DOWNLOAD_DIR "${PSLIB_PREFIX_DIR}/src/${PSLIB_PROJECT}")
+set(PSLIB_DST_DIR "pslib")
+set(PSLIB_INSTALL_ROOT "${THIRD_PARTY_PATH}/install")
+set(PSLIB_INSTALL_DIR ${PSLIB_INSTALL_ROOT}/${PSLIB_DST_DIR})
+set(PSLIB_ROOT ${PSLIB_INSTALL_DIR})
+set(PSLIB_INC_DIR ${PSLIB_ROOT}/include)
+set(PSLIB_LIB_DIR ${PSLIB_ROOT}/lib)
+set(PSLIB_LIB ${PSLIB_LIB_DIR}/libps.so)
+set(PSLIB_VERSION_PY ${PSLIB_DOWNLOAD_DIR}/pslib/version.py)
+set(PSLIB_IOMP_LIB ${PSLIB_LIB_DIR}/libiomp5.so) #todo what is this
+set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_RPATH}" "${PSLIB_ROOT}/lib")
+
+include_directories(${PSLIB_INC_DIR})
+
+file(
+  WRITE ${PSLIB_DOWNLOAD_DIR}/CMakeLists.txt
+  "PROJECT(PSLIB)\n" "cmake_minimum_required(VERSION 3.0)\n"
+  "install(DIRECTORY ${PSLIB_NAME}/include ${PSLIB_NAME}/lib \n"
+  "        DESTINATION ${PSLIB_DST_DIR})\n")
+
+ExternalProject_Add(
+  ${PSLIB_PROJECT}
+  ${EXTERNAL_PROJECT_LOG_ARGS}
+  PREFIX ${PSLIB_PREFIX_DIR}
+  DOWNLOAD_DIR ${PSLIB_DOWNLOAD_DIR}
+  DOWNLOAD_COMMAND wget --no-check-certificate ${PSLIB_URL} -c -q -O
+                   ${PSLIB_NAME}.tar.gz && tar zxvf ${PSLIB_NAME}.tar.gz
+  DOWNLOAD_NO_PROGRESS 1
+  UPDATE_COMMAND ""
+  CMAKE_ARGS -DCMAKE_INSTALL_PREFIX=${PSLIB_INSTALL_ROOT}
+             -DCMAKE_BUILD_TYPE=${THIRD_PARTY_BUILD_TYPE}
+  CMAKE_CACHE_ARGS -DCMAKE_INSTALL_PREFIX:PATH=${PSLIB_INSTALL_ROOT}
+                   -DCMAKE_BUILD_TYPE=${THIRD_PARTY_BUILD_TYPE}
+  BUILD_BYPRODUCTS ${PSLIB_LIB})
+
+add_library(pslib SHARED IMPORTED GLOBAL)
+set_property(TARGET pslib PROPERTY IMPORTED_LOCATION ${PSLIB_LIB})
+add_dependencies(pslib ${PSLIB_PROJECT})

cmake/external/pslib_brpc.cmake

+# Copyright (c) 2018 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+include(ExternalProject)
+
+set(PSLIB_BRPC_PROJECT "extern_pslib_brpc")
+if((NOT DEFINED PSLIB_BRPC_NAME) OR (NOT DEFINED PSLIB_BRPC_URL))
+  message(STATUS "use pre defined download url")
+  set(PSLIB_BRPC_VER
+      "0.1.0"
+      CACHE STRING "" FORCE)
+  set(PSLIB_BRPC_NAME
+      "pslib_brpc"
+      CACHE STRING "" FORCE)
+  set(PSLIB_BRPC_URL
+      "https://pslib.bj.bcebos.com/pslib_brpc.tar.gz"
+      CACHE STRING "" FORCE)
+endif()
+message(
+  STATUS
+    "PSLIB_BRPC_NAME: ${PSLIB_BRPC_NAME}, PSLIB_BRPC_URL: ${PSLIB_BRPC_URL}")
+set(PSLIB_BRPC_PREFIX_DIR "${THIRD_PARTY_PATH}/pslib_brpc")
+set(PSLIB_BRPC_DOWNLOAD_DIR
+    "${PSLIB_BRPC_PREFIX_DIR}/src/${PSLIB_BRPC_PROJECT}")
+set(PSLIB_BRPC_DST_DIR "pslib_brpc")
+set(PSLIB_BRPC_INSTALL_ROOT "${THIRD_PARTY_PATH}/install")
+set(PSLIB_BRPC_INSTALL_DIR ${PSLIB_BRPC_INSTALL_ROOT}/${PSLIB_BRPC_DST_DIR})
+set(PSLIB_BRPC_ROOT ${PSLIB_BRPC_INSTALL_DIR})
+set(PSLIB_BRPC_INC_DIR ${PSLIB_BRPC_ROOT}/include)
+set(PSLIB_BRPC_LIB_DIR ${PSLIB_BRPC_ROOT}/lib)
+set(PSLIB_BRPC_LIB ${PSLIB_BRPC_LIB_DIR}/libbrpc.a)
+set(PSLIB_BRPC_IOMP_LIB ${PSLIB_BRPC_LIB_DIR}/libiomp5.so) #todo what is this
+set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_RPATH}" "${PSLIB_BRPC_ROOT}/lib")
+
+include_directories(${PSLIB_BRPC_INC_DIR})
+
+file(
+  WRITE ${PSLIB_BRPC_DOWNLOAD_DIR}/CMakeLists.txt
+  "PROJECT(PSLIB_BRPC)\n" "cmake_minimum_required(VERSION 3.0)\n"
+  "install(DIRECTORY ${PSLIB_BRPC_NAME}/include ${PSLIB_BRPC_NAME}/lib \n"
+  "        DESTINATION ${PSLIB_BRPC_DST_DIR})\n")
+
+ExternalProject_Add(
+  ${PSLIB_BRPC_PROJECT}
+  ${EXTERNAL_PROJECT_LOG_ARGS}
+  PREFIX ${PSLIB_BRPC_PREFIX_DIR}
+  DOWNLOAD_DIR ${PSLIB_BRPC_DOWNLOAD_DIR}
+  DOWNLOAD_COMMAND
+    wget --no-check-certificate ${PSLIB_BRPC_URL} -c -q -O
+    ${PSLIB_BRPC_NAME}.tar.gz && tar zxvf ${PSLIB_BRPC_NAME}.tar.gz
+  DOWNLOAD_NO_PROGRESS 1
+  UPDATE_COMMAND ""
+  CMAKE_ARGS -DCMAKE_INSTALL_PREFIX=${PSLIB_BRPC_INSTALL_ROOT}
+             -DCMAKE_BUILD_TYPE=${THIRD_PARTY_BUILD_TYPE}
+  CMAKE_CACHE_ARGS -DCMAKE_INSTALL_PREFIX:PATH=${PSLIB_BRPC_INSTALL_ROOT}
+                   -DCMAKE_BUILD_TYPE=${THIRD_PARTY_BUILD_TYPE}
+  BUILD_BYPRODUCTS ${PSLIB_BRPC_LIB})
+
+add_library(pslib_brpc SHARED IMPORTED GLOBAL)
+set_property(TARGET pslib_brpc PROPERTY IMPORTED_LOCATION ${PSLIB_BRPC_LIB})
+add_dependencies(pslib_brpc ${PSLIB_BRPC_PROJECT})

cmake/external/pybind11.cmake

+# Copyright (c) 2016 PaddlePaddle Authors. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+include(ExternalProject)
+
+set(PYBIND_PREFIX_DIR ${THIRD_PARTY_PATH}/pybind)
+set(PYBIND_REPOSITORY ${GIT_URL}/pybind/pybind11.git)
+set(PYBIND_TAG v2.4.3)
+
+set(PYBIND_INCLUDE_DIR ${THIRD_PARTY_PATH}/pybind/src/extern_pybind/include)
+include_directories(${PYBIND_INCLUDE_DIR})
+
+ExternalProject_Add(
+  extern_pybind
+  ${EXTERNAL_PROJECT_LOG_ARGS} ${SHALLOW_CLONE}
+  GIT_REPOSITORY ${PYBIND_REPOSITORY}
+  GIT_TAG ${PYBIND_TAG}
+  PREFIX ${PYBIND_PREFIX_DIR}
+  # If we explicitly leave the `UPDATE_COMMAND` of the ExternalProject_Add
+  # function in CMakeLists blank, it will cause another parameter GIT_TAG
+  # to be modified without triggering incremental compilation, and the
+  # third-party library version changes cannot be incorporated.
+  # reference: https://cmake.org/cmake/help/latest/module/ExternalProject.html
+  UPDATE_COMMAND ""
+  CONFIGURE_COMMAND ""
+  BUILD_COMMAND ""
+  INSTALL_COMMAND ""
+  TEST_COMMAND "")
+
+add_library(pybind INTERFACE)
+
+add_dependencies(pybind extern_pybind)